blob: 5dd1a0cc0c030b9ae1abae736baff8f445ceee7f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Torleif Skår <torleif.skaar AT gmail DOT com>
# Contributor: Kyle Keen <keenerd@gmail.com>
# Contributor: Jared Casper <jaredcasper@gmail.com>
pkgname=magic
pkgver=8.3.529
pkgrel=1
pkgdesc="A VLSI layout system"
_git_url="https://github.com/RTimothyEdwards/magic"
url="http://opencircuitdesign.com/magic/"
arch=('i686' 'x86_64')
license=('LicenseRef-Custom')
depends=(
'glibc'
'tcl'
'tk'
'libx11'
'zlib'
'python'
'bash'
)
makedepends=(
'git'
'gcc'
'make'
'tcsh'
#'ghostscript'
)
optdepends=(
'libgl: OpenGL for performant 2D graphics, needs "glu" as well'
'glu: Vector fonts for OpenGL renderer'
'cairo: 2D accelerated graphics, alternative to OGL'
'blt: to create a tree diagram of the cell hierarchy in a design'
)
_archive="${pkgname}-${pkgver}"
source=(
"${_archive}::git+${_git_url}#tag=${pkgver}"
"0001-set_std_gnu17_default.patch"
)
b2sums=('c2215a49b0225c9a50df421655c3491697cb648c2bceeef8d4d34713491cee4df9d71934336debaca13131d003120b0253bbbce11c2be0a0a107a84251524f61'
'37eaa5bbaab691216ffc06485e6d5d934c74f63e74a876da5bedb0f9fd98f404abfbaa902b9fa979e276e38ba660b4049fbe3d6ff43b591e1d1d3fb2d128eb51')
options=(!ccache)
prepare() {
cd "${_archive}"
# See upstream issue: https://github.com/RTimothyEdwards/magic/issues/401
# for more details about why we need to use C17 + GNU extensions
patch -Np1 < "../0001-set_std_gnu17_default.patch"
}
build() {
cd "${_archive}"
./configure --prefix=/usr
make
}
package() {
cd "${_archive}"
make DESTDIR="$pkgdir" MANDIR=/usr/share/man install
# License
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" LICENSE
# Avoid name collision
mv "$pkgdir/usr/share/man/man1/extcheck.1" "$pkgdir/usr/share/man/man1/extcheck-magic.1"
}
|