PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

# Maintainer: Michael R. Shannon <mrshannon.aerospace@gmail.com>

## This PKGBUILD installs dependencies, provides desktop icons, and patches a
## currently installed version MATLAB.  It should be installed after a manual
## install of MATLAB and will find the location where MATLAB is installed as
## assuming the executable is on the PATH.  This package should not be used with
## the AUR matlab package by Daniel Shub and Ido Rosen.

## The version of this package will always match the MATLAB ## version numbers
## (of which you can find here
## https://en.wikipedia.org/wiki/MATLAB#Release_history) for which this package
## is intended to support.  Please flag as our of date upon a new MATLAB
## release.

## MATLAB is a commercial product with a paid license, this package does not
## provide MATLAB, it only provides dependencies and fixes to make it run better
## on Arch Linux.

## Much thanks to Daniel Shub and Ido Rosen whose matlab PKGBUILD served as a
## guide when making this one.

pkgname=matlab-support
pkgver=9.2.0
pkgrel=2
pkgdesc='Provides dependencies and common fixes for MATLAB.'
arch=('x86_64')
url='http://www.mathworks.com'
license=(custom)
depends=('libx11'
         'libxext'
         'libxt'
         'jre7-openjdk'
         'libselinux')
optdepends=('gcc49: For MEX support')
makedepends=('gendesk')
provides=('matlab')
conflicts=('matlab')
install=${pkgname}.install
source=('https://upload.wikimedia.org/wikipedia/commons/2/21/Matlab_Logo.png')
sha512sums=('ba72458379c89b22a27d1d7e357cefae4437fa28caac47b26ccd4f5b01b8cbc2c000baf38b5a52565f29b14e6da922bc3dc14bc5d47fa682fb6871422a59c397')

prepare() {
    msg2 'Creating desktop file'
    gendesk -f -n --pkgname 'matlab' \
        --pkgdesc 'A high-level language for numerical computation and visualization.' \
        --categories 'Development;Education;science;Mathematics;IDE' \
        --exec 'matlab -desktop -nosplash' \
        --mimetypes 'text/x-matlab' \
        "${srcdir}/matlab.desktop" >/dev/null 

    msg2 'Creating command line executable'
    echo -e "#!/bin/sh\nmatlab -nodesktop -nosplash" > "${srcdir}/matlab-cli"

    # If you never let MATLAB connect to the internet or run MATLAB on a server
    # the Java version it includes should be fine but otherwise the outdated
    # Java that ships with MATLAB is a security risk.
    msg2 'Creating profile.d files'
    echo -e "export MATLAB_JAVA=/usr/lib/jvm/java-7-openjdk/jre" > "${srcdir}/matlab.sh"
    echo -e "setenv MATLAB_JAVA /usr/lib/jvm/java-7-openjdk/jre" > "${srcdir}/matlab.csh"
}

package() {
    msg2 'Installing desktop files'
    install -D -m644 "matlab.desktop" "${pkgdir}/usr/share/applications/matlab.desktop"
    install -D -m644 "Matlab_Logo.png" "${pkgdir}/usr/share/pixmaps/matlab.png"

    msg2 'Installing command line executable'
    install -D -m755 'matlab-cli' "${pkgdir}/usr/bin/matlab-cli"

    msg2 'Installing profile.d files'
    install -D -m644 'matlab.sh' "${pkgdir}/etc/profile.d/matlab.sh"
    install -D -m644 'matlab.csh' "${pkgdir}/etc/profile.d/matlab.csh"
}