blob: 54ee861b0fde98a0e8f59a6e6909813d8453b6e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: bobpaul
_pkgbase=mautrix-facebook
pkgname="${_pkgbase}-git"
pkgver=r964.2ab4342
pkgrel=2
pkgdesc="A double puppeting Facebook bridge with multi-user support for Hangouts"
arch=(any)
conflicts=(mautrix-facebook)
license=('AGPL-3.0-or-later')
url="https://github.com/mautrix/facebook"
depends=(
'python'
'python-aiohttp'
'python-aiohttp-socks'
'python-attrs'
'python-asyncpg'
'python-commonmark'
'python-magic'
'python-mautrix' # AUR
'python-olm'
'python-paho-mqtt'
'python-pillow'
'python-pycryptodome'
'python-python-socks'
'python-ruamel-yaml'
'python-setuptools'
'python-unpaddedbase64'
'python-yarl'
'python-zstandard'
)
makedepends=('git')
optdepends=('python-aiosqlite: for sqlite database backend')
source=(
"${_pkgbase}::git+https://github.com/tulir/${_pkgbase}"
"usr-share.patch"
"README"
"sysusers-mautrix-facebook.conf"
"tmpfiles-mautrix-facebook.conf"
"${_pkgbase}.service"
)
sha256sums=(
'SKIP'
'd513b67b7ed70a7d4b19aece23d820e309629bc25131caf136101bb2508fc075'
'ee0cd11812d2c3e4d57cfb534a9302374d1477c05c55bfbfeb5816aefc0a593f'
'd981fb6fef944b83a4089683075ab2ae1cf095a6814e4d3bdce500d3309cb617'
'9e7d00ea24067447fde0f3c4c08ea70760db85975d93496ed82f597cd8c863d6'
'a405ddaff8d16e09caae4346b4721727c1d3e86ca3d8325c54e0180b771bc12f'
)
pkgver() {
cd "$srcdir/${_pkgbase}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/${_pkgbase}"
git reset --hard
echo 'Apply patch to follow fileplacement guidelines per `man heir`'
patch < ../usr-share.patch
echo 'Applying patch to permit use of newest mautrix version'
sed -i 's/^mautrix==/mautrix>=/' requirements.txt
}
package() {
cd "$srcdir/${_pkgbase}"
python setup.py install --root="$pkgdir/" --optimize=1
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "$srcdir/"
install -Dm644 "$srcdir"/README -t "$pkgdir"/etc/synapse/mautrix-facebook/
install -Dm644 ${_pkgbase}.service -t "${pkgdir}"/usr/lib/systemd/system/
install -Dm644 "$srcdir"/sysusers-mautrix-facebook.conf "$pkgdir"/usr/lib/sysusers.d/mautrix-facebook.conf
install -Dm644 "$srcdir"/tmpfiles-mautrix-facebook.conf "$pkgdir"/usr/lib/tmpfiles.d/mautrix-facebook.conf
}
|