blob: 6b4da2900a48b5f812876821d93d7c5cdc0aa9dc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Mario Finelli <mario at finel dot li>
pkgname=mdq
pkgver=0.10.0
pkgrel=1
pkgdesc="like jq but for Markdown: find specific elements in a md doc"
arch=(x86_64)
url=https://github.com/yshavit/mdq
license=(Apache-2.0 MIT)
depends=(gcc-libs glibc)
makedepends=(cargo)
source=($url/archive/v$pkgver/$pkgname-$pkgver.tar.gz)
sha256sums=('81d6ecb8602930483c234cc3a4242f8c66e82d93010114062b394d46f7c464ef')
prepare() {
cd $pkgname-$pkgver
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd $pkgname-$pkgver
cargo build --all-features --frozen --release
}
check() {
cd $pkgname-$pkgver
cargo test --all-features --frozen
}
package() {
cd $pkgname-$pkgver
install -Dm0755 target/release/mdq "$pkgdir/usr/bin/mdq"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 LICENSE-MIT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set ts=2 sw=2 et:
|