blob: 6d5d1ba171f8c563668bb3c6d2a9d7e8c9c7db51 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Misaka13514 <Misaka13514 at gmail dot com>
# Contributor: Alex Sarum <rum.274.4 at gmail dot com>
# Contributor: Gavin Lloyd <gavinhungry@gmail.com>
# Contributor: Bailey Fox <bfox200012@gmail.com>
# Contributor: Tony Lambiris <tony@libpcap.net>
pkgname=meanalyzer
_pkgname=MEAnalyzer
_tag=v1.307.0-r345
_pkgver="${_tag#v}"
pkgver=1.307.0.r345
pkgrel=1
pkgdesc="Intel Engine & Graphics Firmware Analysis Tool"
arch=('any')
url="https://github.com/platomav/MEAnalyzer"
license=('BSD-2-Clause-Patent')
depends=('python' 'python-colorama' 'python-crccheck' 'python-pltable')
makedepends=('dos2unix')
conflicts=("${pkgname}-git")
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${_tag}.tar.gz")
sha256sums=('5d52b38489edeb43cd5c27625bb4d946bff8290cac4158e06abd706fa2b035f6')
pkgver() {
cd "${_pkgname}-${_pkgver}"
printf "%s.%s" \
"$(sed -n 's/.*ME Analyzer v\([0-9]\+\.[0-9]\+\.[0-9]\+\).*/\1/p' MEA.py)" \
"$(sed -n 's/.*Revision \(r[0-9]\+\).*/\1/p' MEA.dat)"
}
prepare() {
cd "${_pkgname}-${_pkgver}"
dos2unix *
}
package() {
cd "${_pkgname}-${_pkgver}"
install -Dm644 -t "${pkgdir}/usr/lib/${pkgname}" *.dat
install -Dm755 -t "${pkgdir}/usr/lib/${pkgname}" *.py
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" README.md
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
install -dm755 "${pkgdir}/usr/bin"
ln -s "/usr/lib/${pkgname}/MEA.py" "${pkgdir}/usr/bin/${pkgname}"
}
|