blob: 15024c1c870e2a108f1b1092b611fa9baba314e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Christian Schendel (doppelhelix@gmail.com)
pkgname=mediaelch-git
pkgver=2.12.0.r32.g5bff30e8
pkgrel=1
pkgdesc='MediaElch is a MediaManager for Kodi'
url='https://github.com/Komet/MediaElch'
arch=(
x86_64
)
license=(
LGPL-3.0-or-later
)
depends=(
glibc
gcc-libs
libmediainfo
qt6-declarative
qt6-multimedia
qt6-svg
quazip-qt6
)
makedepends=(
cmake
git
ninja
qt6-tools
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --long --tags | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
local cmake_options=(
-S "$srcdir/${pkgname%-git}"
-B build
-DCMAKE_INSTALL_PREFIX=/usr
-DCMAKE_BUILD_TYPE=None
-DDISABLE_UPDATER=ON
-DUSE_EXTERN_QUAZIP=ON
-DMEDIAELCH_FORCE_QT5=OFF
-DMEDIAELCH_FORCE_QT6=ON
-Wno-dev
-G Ninja
)
cmake "${cmake_options[@]}"
ninja -C build
}
package() {
DESTDIR="${pkgdir}" ninja -C build install
cd "$srcdir/${pkgname%-git}"
install -Dm0644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" README.md CONTRIBUTING.md CHANGELOG.md
}
# vim: set ts=4 sw=4 et:
|