PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: Imperator Storm <imperatorstorm11@protonmail.com
# shellcheck disable=SC2034,SC2154,SC2164,SC2148
pkgname=memsed-git
pkgver=0.1.r19.gcafbbe9
pkgrel=2
pkgdesc="MEMory Search and EDit for Linux, inspired by Cheat Engine"
arch=(x86_64)
url="https://github.com/Willy-JL/MemSed"
license=('GPL-3.0-only')
groups=()
depends=(glibc sdl3)
makedepends=(git cmake 'python>=3.10' python-jinja 'python-ply>=3.11')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
options=()
source=('memsed::git+https://github.com/Willy-JL/MemSed.git'
		'memsed-dear_bindings::git+https://github.com/dearimgui/dear_bindings.git'
		'memsed-imgui::git+https://github.com/ocornut/imgui.git'
		'memsed-glad::git+https://github.com/Dav1dde/glad.git'
		dont_werror.patch)
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            '46a844e3391423880970798d223d1c0c6b0fbcf4f7e7b42025fc41352098a916')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	git describe --tags --long --abbrev=7 | sed 's/^memsed.//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	env -C "$srcdir/${pkgname%-git}" patch -tp1 <dont_werror.patch
	cd "$srcdir/${pkgname%-git}"
	git submodule init
	git config submodule.lib/vendor/dear_bindings.url "$srcdir/memsed-dear_bindings"
	git config submodule.lib/vendor/imgui.url "$srcdir/memsed-imgui"
	#//TODO: figure out a way to use system glad generator
	git config submodule.lib/vendor/glad.url "$srcdir/memsed-glad"
	git -c protocol.file.allow=always submodule update \
		lib/vendor/imgui lib/vendor/dear_bindings lib/vendor/glad
}

build() {
	cd "$srcdir/${pkgname%-git}"
	cmake -B build -DCMAKE_BUILD_TYPE=None -DCMAKE_INSTALL_PREFIX=/usr -Wno-dev \
		-DMEMSED_VENDORED_SDL3=OFF -DMEMSED_PYTHON_VENV=OFF
	cmake --build build
}

#check() {
#	cd "$srcdir/${pkgname%-git}"
#}

package() {
	cd "$srcdir/${pkgname%-git}"
	#DESTDIR="$pkgdir/" cmake --install build //NYI
	install -D -m755 "$srcdir/${pkgname%-git}"/build/memsed "${pkgdir}"/usr/bin/memsed
    install -D -m644 "$srcdir/${pkgname%-git}"/LICENSE  "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE
}