blob: d5c62bd002a045ad69d7966bef1317984a73e8a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
_pkgname=mhwaveedit
pkgname="${_pkgname}-git"
pkgver=1.4.24.r149.8a24f6a
pkgrel=1
pkgdesc="A simple and fast GTK2 audio editor (git version)"
arch=('x86_64')
url="https://github.com/magnush/mhwaveedit"
license=('GPL2')
depends=('gtk2' 'hicolor-icon-theme' 'sdl')
makedepends=('alsa-lib' 'git' 'ladspa' 'libpulse' 'libsamplerate' 'libsndfile'
'jack')
groups=('pro-audio')
provides=("${_pkgname}" "${_pkgname}=${pkgver//.r*/}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://salsa.debian.org/multimedia-team/${_pkgname}.git/")
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
local ver=$(grep ^MHW_VERSION configure | cut -d = -f 2)
echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${_pkgname}"
./configure \
--prefix=/usr \
--with-double-samples \
--without-arts \
--without-esound \
--without-oss
make
}
package() {
depends+=('libasound.so' 'libjack.so' 'libpulse.so' 'libsamplerate.so' 'libsndfile.so')
cd "${srcdir}/${_pkgname}"
make DESTDIR="${pkgdir}/" install
}
|