blob: 866c1f31c79fabf56c63b415a26925c464c329c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Mike Swanson <mikeonthecomputer@gmail.com>
# Contributor: Buce <dmbuce@gmail.com>
# Contributor: Duncan Bain <duncanjbain@gmail.com>
# Contributor: Maxwell Pray a.k.a. Synthead <synthead@gmail.com>
_pkgname=Minecraft-Overviewer
pkgname=(${_pkgname,,} ${_pkgname,,}-docs)
pkgver=0.16.30
_gitcommit=649a20e9020a21cf868fae6c16f525b4d93cddaa
pkgrel=1
pkgdesc="Render large resolution images of a Minecraft map with a web UI"
arch=('x86_64')
url="https://github.com/overviewer/${_pkgname}"
license=('GPL3')
depends=('python' 'python-pillow' 'python-numpy')
makedepends=('python-sphinx')
source=("$url/archive/$_gitcommit.tar.gz")
b2sums=('3f14165f8af877a4912318aca3b63954f73a376c2dad0c7ac2c8262c86c7456032855c49d20083c7a809f336e36ca917299ae810508e6127dba41ebc36ca4bdf')
build() {
cd "${_pkgname}-$_gitcommit"
python setup.py build
cd ./docs
make html
}
package_minecraft-overviewer() {
cd "${_pkgname}-$_gitcommit"
python setup.py install --prefix=/usr --root="$pkgdir"
}
package_minecraft-overviewer-docs() {
arch=('any')
depends=()
cd "${_pkgname}-$_gitcommit/docs/_build/html"
install -d "$pkgdir/usr/share/doc/${pkgbase}/html"
cp -r -t "$pkgdir/usr/share/doc/${pkgbase}/html" -- *
}
|