blob: 760276c18fbaee46f4c4f0abca7e4d96f06a09f2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: Andrew Sun <adsun701 at gmail dot com>
_name="glibmm"
pkgname="mingw-w64-${_name}"
pkgver=2.66.7
pkgrel=1
pkgdesc="C++ bindings for GLib (mingw-w64)"
arch=('any')
url="https://www.gtkmm.org"
license=('LGPL-2.1-or-later')
depends=('mingw-w64-crt' 'mingw-w64-glib2>=2.61.2' 'mingw-w64-libsigc++>=2.9.1')
makedepends=('mingw-w64-meson>=0.55' 'mm-common')
options=('!strip' '!buildflags' 'staticlibs')
_pkgsrc="${_name}-${pkgver}"
source=("${_pkgsrc}.tar.xz::https://download.gnome.org/sources/${_name}/${pkgver%.*}/${_pkgsrc}.tar.xz")
sha256sums=('fe02c1e5f5825940d82b56b6ec31a12c06c05c1583cfe62f934d0763e1e542b3')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
build() {
cd "${srcdir}"
for _arch in ${_architectures}; do
mkdir -p "${_pkgsrc}/build-${_arch}"
${_arch}-meson "${_pkgsrc}" "${_pkgsrc}/build-${_arch}" \
-D maintainer-mode=true \
-D build-documentation=false \
-D build-examples=false
meson compile -C "${_pkgsrc}/build-${_arch}"
done
}
package() {
cd "${srcdir}"
for _arch in ${_architectures}; do
meson install -C "${_pkgsrc}/build-${_arch}" --destdir "${pkgdir}"
find "${pkgdir}/usr/${_arch}" -name '*.exe' -exec "${_arch}-strip" "{}" \;
find "${pkgdir}/usr/${_arch}" -name '*.dll' -exec "${_arch}-strip" --strip-unneeded "{}" \;
find "${pkgdir}/usr/${_arch}" \( -name '*.a' -o -name '*.dll' \) -exec "${_arch}-strip" -g '{}' ';'
done
}
# vim: ts=2 sw=2 et:
|