blob: 79c1ce9d226b428dd9fc8ec9d0fab8c85eaffc22 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Mladen Milinkovic <maxrd2@smoothware.net>
_pkgname=kinit
pkgname=mingw-w64-$_pkgname
pkgver=5.76.0
pkgrel=1
arch=(any)
pkgdesc="Process launcher to speed up launching KDE applications (mingw-w64)"
license=("LGPL")
depends=(mingw-w64-kio)
groups=(mingw-w64-kf5)
makedepends=(mingw-w64-extra-cmake-modules mingw-w64-qt5-tools)
options=(staticlibs !strip !buildflags)
url="https://community.kde.org/Frameworks"
source=("http://download.kde.org/stable/frameworks/${pkgver%.*}/$_pkgname-${pkgver}.tar.xz"{,.sig}
"org.kde.klauncher5.service")
sha256sums=('a5b63c10b4fc5efcbb5f92b7bce928b4a4880c0ad5d12ff12518106b09239546'
'SKIP'
'5b242720243f720221284489d739b9caa3b25717c8883bfa0f1883fc7d87edf6')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd $_pkgname-$pkgver
# remove doctools stuff
sed -e '/find_package.*KF5DocTools/d;/kdoctools_install/d' -i CMakeLists.txt
}
build() {
cd $_pkgname-$pkgver
for _arch in ${_architectures}; do
unset LDFLAGS
mkdir -p "build-${_arch}" && pushd "build-${_arch}"
${_arch}-cmake \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_LIBDIR=lib \
-DBUILD_TESTING=OFF \
-DKDE_INSTALL_DBUSDIR="/usr/${_arch}/share/dbus-1" \
..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}/${pkgname#mingw-w64-}-$pkgver/build-${_arch}"
make DESTDIR="$pkgdir" install
install -m644 -D -t "${pkgdir}/usr/${_arch}/share/dbus-1/services" "${srcdir}/org.kde.klauncher5.service"
find "$pkgdir/usr/${_arch}" -name '*.exe' -exec ${_arch}-strip {} \;
find "$pkgdir/usr/${_arch}" -name '*.dll' -exec ${_arch}-strip --strip-unneeded {} \;
find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs ${_arch}-strip -g
done
}
|