blob: 444c1a2ff9ca050c0f76a8064a9c0b8a292eec96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Mladen Milinkovic <maxrd2@smoothware.net>
pkgname=mingw-w64-kwidgetsaddons
pkgver=5.76.0
pkgrel=2
arch=(any)
pkgdesc="Addons to QtWidgets (mingw-w64)"
license=("LGPL")
depends=(mingw-w64-qt5-base)
groups=(mingw-w64-kf5)
makedepends=(mingw-w64-cmake mingw-w64-extra-cmake-modules mingw-w64-qt5-tools)
options=(staticlibs !strip !buildflags)
url="https://community.kde.org/Frameworks"
source=("http://download.kde.org/stable/frameworks/${pkgver%.*}/kwidgetsaddons-${pkgver}.tar.xz"{,.sig})
sha256sums=('ab7aa94bb1f63e5bea5cf461349c1add96fd608a73c5b7c9d374e6bf035fcac6'
'SKIP')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
build() {
cd kwidgetsaddons-$pkgver
for _arch in ${_architectures}; do
unset LDFLAGS
mkdir "build-${_arch}" && pushd "build-${_arch}"
${_arch}-cmake \
-DCMAKE_BUILD_TYPE=Release \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
-DBUILD_TESTING=OFF \
..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}/${pkgname#mingw-w64-}-$pkgver/build-${_arch}"
make DESTDIR="$pkgdir" install
find "$pkgdir/usr/${_arch}" -name '*.dll' -exec ${_arch}-strip --strip-unneeded {} \;
find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs ${_arch}-strip -g
rm -rf "$pkgdir/usr/${_arch}/share"
done
}
|