blob: 9db2c385d86b0082d0d8ca66ab114ad64e50d508 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Vaporeon <vaporeon@vaporeon.io>
# Contributor: xantares
pkgname=mingw-w64-libzip
pkgver=1.10.1
pkgrel=1
pkgdesc="A C library for reading, creating, and modifying zip archives (mingw-w64)"
url="http://www.nih.at/libzip/index.html"
license=('BSD')
arch=(any)
depends=('mingw-w64-xz' 'mingw-w64-zlib' 'mingw-w64-bzip2' 'mingw-w64-openssl' 'mingw-w64-gnutls')
makedepends=('mingw-w64-cmake' 'ninja')
options=('staticlibs' '!buildflags' '!strip')
source=("http://www.nih.at/libzip/libzip-${pkgver}.tar.xz")
sha256sums=('dc3c8d5b4c8bbd09626864f6bcf93de701540f761d76b85d7c7d710f4bd90318')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
_pkgname="libzip"
build() {
for _arch in ${_architectures}; do
${_arch}-cmake -S ${_pkgname}-${pkgver} -B build/${_arch}-static -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_DOC=OFF \
-DBUILD_EXAMPLES=OFF \
-DBUILD_REGRESS=OFF \
-DBUILD_TOOLS=OFF \
-DBUILD_SHARED_LIBS=OFF
${_arch}-cmake -S ${_pkgname}-${pkgver} -B build/${_arch} -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_DOC=OFF \
-DBUILD_EXAMPLES=OFF \
-DBUILD_REGRESS=OFF \
-DBUILD_TOOLS=OFF
cmake --build build/${_arch}-static
cmake --build build/${_arch}
done
}
package() {
for _arch in ${_architectures}; do
DESTDIR="${pkgdir}" cmake --install build/${_arch}-static
DESTDIR="${pkgdir}" cmake --install build/${_arch}
${_arch}-strip --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "${pkgdir}"/usr/${_arch}/lib/*.a
done
}
|