PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: HurricanePootis <hurricanepootis@protonmail.com>
pkgname=miro-pdf-git
pkgver=0.7.0.r2.g5adfc64
pkgrel=1
pkgdesc="A native pdf viewer for Windows and Linux (Wayland/X11) with configurable keybindings."
arch=('x86_64')
url="https://github.com/vincent-uden/miro"
license=('AGPL-3.0-or-later')
depends=('glibc' 'gcc-libs' 'fontconfig')
install=$pkgname.install
makedepends=('cargo' 'git' 'clang')
provides=(${pkgname::-4})
conflicts=(${pkgname::-4})
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')

pkgver(){
	cd "$srcdir/${pkgname}"
	git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//g'
}

prepare() {
	cd "$srcdir/${pkgname}"
	export RUSTUP_TOOLCHAIN=stable
	cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
	cd "$srcdir/${pkgname}"
	export RUSTUP_TOOLCHAIN=stable
	export CARGO_TARGET_DIR=target
	export CFLAGS+=" -ffat-lto-objects"
	cargo build --frozen --release --all-features
}

package() {
	cd "$srcdir/${pkgname}"
	install -Dm755 "$srcdir/${pkgname}/target/release/${pkgname::-4}" "$pkgdir/usr/bin/${pkgname::-4}"
	install -Dm644 "$srcdir/${pkgname}/assets/default.conf" "$pkgdir/usr/share/${pkgname::-4}/miro.conf"
}