blob: b369a26a46d62ab49473129db9a53128754ae89f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: allddd <me (at) allddd (dot) onl>
pkgname=mkinitcpio-extras
pkgver=5
pkgrel=1
pkgdesc='Collection of mkinitcpio hooks for busybox based initramfs'
arch=(
'aarch64'
'armv7h'
'i686'
'riscv64'
'x86_64'
)
url='https://gitlab.com/allddd/mkinitcpio-extras'
license=('GPL-2.0-only')
depends=('mkinitcpio')
makedepends=('linux-api-headers')
optdepends=(
'dropbear: required for dropbear'
'tinyssh: required for tinyssh'
)
provides=(
'mkinitcpio-dropbear'
'mkinitcpio-netconf'
'mkinitcpio-nfs-utils'
'mkinitcpio-tinyssh'
)
conflicts=(
'mkinitcpio-dropbear'
'mkinitcpio-netconf'
'mkinitcpio-nfs-utils'
'mkinitcpio-tinyssh'
)
options=('!debug')
source=("${url}/-/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
sha256sums=('1fccd7c5053596944bb757f0ab0bf2266bf425c48e7469950fc91ae1813f8ba5')
prepare() {
cd "${srcdir}/${pkgname}-v${pkgver}/lib/klibc"
mkdir -p ./linux/include/
ln -s /usr/include/{asm,asm-generic,linux} ./linux/include/
}
build() {
cd "${srcdir}/${pkgname}-v${pkgver}/lib/klibc"
make
}
package() {
cd "${srcdir}/${pkgname}-v${pkgver}"
for _name in ipconfig nfsmount; do
install -Dm755 "./lib/klibc/usr/kinit/${_name}/static/${_name}" -t "${pkgdir}/usr/lib/initcpio/"
done
for _name in */; do
_name=${_name%/}
_hook="./${_name}/${_name}_hook"
_install="./${_name}/${_name}_install"
[[ -f "${_hook}" && -f "${_install}" ]] || continue
install -Dm644 "${_hook}" "${pkgdir}/usr/lib/initcpio/hooks/${_name}"
install -Dm644 "${_install}" "${pkgdir}/usr/lib/initcpio/install/${_name}"
done
}
# vim: ts=4 sw=4 et:
|