summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0d59b7e6cce54fdc13a5fe14758eef97181004ad (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Christian Hesse <mail@eworm.de>

pkgname=mkinitcpio-ykfde-git
pkgver=0.6.4.r0.g95f195c
pkgrel=1
pkgdesc='Full disk encryption with Yubikey (Yubico key) - git checkout'
arch=('i686' 'x86_64')
url='https://github.com/eworm-de/mkinitcpio-ykfde'
license=('GPL')
depends=('yubikey-personalization' 'cryptsetup' 'iniparser' 'libarchive' 'keyutils')
makedepends=('git' 'markdown')
conflicts=('mkinitcpio-ykfde')
provides=('mkinitcpio-ykfde')
install=mkinitcpio-ykfde.install
source=('git://github.com/eworm-de/mkinitcpio-ykfde.git')
sha256sums=('SKIP')
backup=('etc/ykfde.conf')

pkgver() {
	cd mkinitcpio-ykfde/

	# usauall I use 'git describe' with '--tags'
	# skip it here as we want signed tags only
	if GITTAG="$(git describe --abbrev=0 2>/dev/null)"; then
		printf '%s.r%s.g%s' \
			"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
			"$(git rev-list --count ${GITTAG}..)" \
			"$(git log -1 --format='%h')"
	else
		printf '0.r%s.g%s' \
			"$(git rev-list --count master)" \
			"$(git log -1 --format='%h')"
	fi
}

build() {
	cd mkinitcpio-ykfde/

	make
}

package() {
	cd mkinitcpio-ykfde/

	make DESTDIR=${pkgdir} install-mkinitcpio
}