blob: 1de5bc1c4a6fcb7e543ba0964a9c5fae495c5a06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: matthias.lisin
pkgname="mockery"
pkgver=3.7.0
pkgrel=1
pkgdesc="A mock code autogenerator for Go"
arch=(
'aarch64'
'x86_64'
)
url="https://vektra.github.io/mockery"
_url="https://github.com/vektra/${pkgname}"
license=(
'BSD-3-Clause'
)
depends=(
'glibc'
)
makedepends=(
'go'
)
provides=(
"golang-mockery=${pkgver}"
)
conflicts=(
'golang-mockery'
)
replaces=(
'golang-mockery'
)
_pkgsrc="${_url##*/}-${pkgver}"
source=(
"${_url}/archive/refs/tags/v${pkgver}/${_pkgsrc}.tar.gz"
)
sha256sums=('bd82f58e9c17d84e9c933a89375c6a18c4d79909032f22885e4504c519f4a60d')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
go get -modcacherw -v ./...
mkdir -p "completions"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
go build -v -o "build/${pkgname}" -ldflags "\
-X ${_url#https://}/v2/pkg/logging.SemVer=${pkgver}" \
.
# --config='/dev/null' to avoid reading .mockery.yaml
for _sh in bash fish powershell zsh; do
./"build/${pkgname}" --config='/dev/null' completion "${_sh}" > "completions/${pkgname}.${_sh}"
done
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# go test ./...
# }
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "completions"
install -vDm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -vDm644 "${pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${pkgname}.ps1"
install -vDm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
}
|