blob: a97d5d5b5d294cd0148e865330fde4a15c04f40e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Nissar Chababy <funilrys at outlook dot com>
# Ex-Maintainer: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
pkgname=mod_nss
pkgver=1.0.14
pkgrel=1
pkgdesc="SSL/TLS module for the Apache HTTP server"
arch=(i686 x86_64)
url="https://fedorahosted.org/mod_nss/"
license=(Apache)
depends=(apache apr nspr nss)
backup=(etc/httpd/conf/extra/nss.conf
etc/httpd/alias/secmod.db
etc/httpd/alias/cert8.db
etc/httpd/alias/key3.db
etc/httpd/alias/install.log)
install=mod_nss.install
# Patches are from Fedora
source=("https://releases.pagure.org/mod_nss/mod_nss-${pkgver}.tar.gz")
sha512sums=('8f3279280c019f71b926bbebdcf619bfb3a91ea23ad64193e54bae2a97eba75fe7571597e6a2e34bd702b499d100f75bf38f82f9840822fef42acaa3b205b183')
prepare() {
cd "${pkgname}-${pkgver}"
# Update timestamps to avoid regeneration
touch nss_expr_*.[chyl]
}
build() {
cd "${pkgname}-${pkgver}"
export APXS=/usr/bin/apxs
autoreconf -vfi
./configure \
--prefix=/usr \
--with-apr-config \
--enable-ecc
make all
}
check() {
cd "${pkgname}-${pkgver}"
make check
}
package() {
cd "${pkgname}-${pkgver}"
install -dm755 "${pkgdir}/etc/httpd/conf/extra/"
install -dm755 "${pkgdir}/etc/httpd/alias/"
install -dm755 "${pkgdir}/usr/lib/httpd/modules/"
install -dm755 "${pkgdir}/usr/bin/"
install -dm755 "${pkgdir}/usr/share/man/man8/"
install -m644 gencert.8 "${pkgdir}/usr/share/man/man8/"
install -m644 nss_pcache.8 "${pkgdir}/usr/share/man/man8/"
install -m644 nss.conf "${pkgdir}/etc/httpd/conf/extra/"
install -m755 .libs/libmodnss.so "${pkgdir}/usr/lib/httpd/modules/"
install -m755 nss_pcache "${pkgdir}/usr/bin/"
install -m755 gencert "${pkgdir}/usr/bin/"
perl -pi -e "s:/usr/lib:/usr/bin:" "${pkgdir}/usr/bin/gencert"
ln -s ../../../usr/lib/libnssckbi.so "${pkgdir}/etc/httpd/alias/"
touch "${pkgdir}/etc/httpd/alias/secmod.db"
touch "${pkgdir}/etc/httpd/alias/cert8.db"
touch "${pkgdir}/etc/httpd/alias/key3.db"
touch "${pkgdir}/etc/httpd/alias/install.log"
}
|