blob: d5918e6ed4581a45443a0fff6e30ef24c3821c13 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Peter Jung <ptr1337@cachyos.org>
# Maintainer: asyync1024 <asyync1024 at proton dot me>
_reponame=mold
pkgname=${_reponame}-git
pkgver=3.0.0.r44.g418dbb77
pkgrel=1
pkgdesc='A Modern Linker in Rust'
arch=('x86_64')
url="https://github.com/rui314/$_reponame"
license=('MIT')
# bundled: mimalloc
depends=(
glibc
libgcc
zstd
)
makedepends=(
cargo
git
)
checkdepends_aarch64=(clang)
source=("git+${url}.git")
b2sums=('SKIP')
provides=("$_reponame=$pkgver")
conflicts=("$_reponame")
options=(!lto)
pkgver() {
cd "$_reponame"
git describe --long --tags | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
cd "$_reponame"
# Fix missing FULL RELRO on mold-wrapper.so
sed -i '/command.arg("-ldl")/ s/arg.*/args(["-ldl", "-Wl,-z,relro,-z,now"]);/' elf/build.rs
cargo fetch --locked --target host-tuple
}
build() {
cd "$_reponame"
# Option(s) below are used by both build() and check()
export ZSTD_SYS_USE_PKG_CONFIG=1
cargo build --release --frozen --package mold
}
check() {
cd "$_reponame"
cargo test --frozen
}
package() {
PREFIX="$pkgdir/usr" LIBEXECDIR="$PREFIX/lib" "$_reponame/install-mold.sh"
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$_reponame/LICENSE"
}
# vim: ts=2 sw=2 et:
|