blob: 9d64babef87dad3a227601afa264e754b6dcbcbd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Jed Brown <jed@59A2.org>
# Contributor: Jed Brown <jed@59A2.org>
# Contributor: George Eleftheriou <eleftg>
pkgname=mpich
pkgver=4.2.0
pkgrel=1
pkgdesc="An improved implementation of the Message Passing Interface."
url="https://mpich.org"
arch=(x86_64)
license=("custom")
replaces=(mpich2)
depends=('gcc-fortran' 'libxml2' 'openssh' 'numactl' 'pciutils' 'hwloc' 'bash')
makedepends=(texlive-core sowing autoconf python)
optdepends=(perl python)
install="${pkgname}.install"
source=("https://www.mpich.org/static/downloads/${pkgver}/${pkgname}-${pkgver}.tar.gz"
"mpich.profile")
sha256sums=('a64a66781b9e5312ad052d32689e23252f745b27ee8818ac2ac0c8209bc0b90e'
'b9716439a544511bf88618edeb40c3eb80f1b5d0d9369c30d750251feed02284')
options=('!libtool')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
# CFLAGS etc are normally written into the wrapper compilers. This
# gives surprising results, e.g. when the user wants to compile their
# program without optimization.
export MPICHLIB_CFLAGS="${CFLAGS}"; unset CFLAGS
export MPICHLIB_CXXFLAGS="${CXXFLAGS}"; unset CXXFLAGS
export MPICHLIB_CPPFLAGS="${CPPFLAGS}"; unset CPPFLAGS
export MPICHLIB_FFLAGS="${FFLAGS}"; unset FFLAGS
export MPICHLIB_FCFLAGS="${FCFLAGS}"; unset FCFLAGS
export MPICHLIB_LDFLAGS="${LDFLAGS}"; unset LDFLAGS
mkdir -p build
cd build
../configure --prefix=/opt/mpich \
--with-device=ch4:ucx \
--with-hwloc \
--without-java \
--without-ze \
--enable-error-checking=runtime \
--enable-error-messages=all \
CC=gcc CXX=g++ FC=gfortran
make
make mandoc
}
check() {
cd ${srcdir}/${pkgname}-${pkgver}/build
# Disabled for mpich-3.4 due to json-c test failure
# make check
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}/build"
make DESTDIR="${pkgdir}" install
ln -sf mpiexec.hydra "${pkgdir}/opt/mpich/bin/mpirun.hydra"
install -D -m644 "${srcdir}/${pkgname}-${pkgver}/COPYRIGHT" "${pkgdir}/usr/share/licenses/mpich/license.txt"
install -D -m755 "${srcdir}/${pkgname}.profile" "${pkgdir}/etc/profile.d/mpich.sh"
mkdir -p "${pkgdir}/etc/ld.so.conf.d"
echo /opt/mpich/lib > "${pkgdir}/etc/ld.so.conf.d/mpich.conf"
}
|