blob: 240f1d1ba438f963cd23e4b2c0ad4233d36c7b3d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: lod <aur@cyber-anlage.de>
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Eivind Uggedal <eivind@uggedal.com>
_pkgname=mpv
pkgname=${_pkgname}-pipewire
_tag='v0.34.1' # git rev-parse v${pkgver}
pkgver=0.34.1
pkgrel=2
pkgdesc='a free, open source, and cross-platform media player including an experimental PipeWire audio backend'
arch=('x86_64')
# We link against libraries that are licensed GPLv3 explicitly, so our
# package is GPLv3 only as well. (Is this still correct?)
license=('GPL3')
url='https://mpv.io/'
depends=('alsa-lib' 'libasound.so' 'desktop-file-utils' 'ffmpeg' 'libavcodec.so' 'libavdevice.so'
'libavfilter.so' 'libavformat.so' 'libavutil.so' 'libswresample.so' 'libswscale.so'
'glibc' 'hicolor-icon-theme' 'jack' 'libjack.so' 'lcms2' 'liblcms2.so' 'libarchive'
'libarchive.so' 'libass' 'libass.so' 'libbluray' 'libbluray.so' 'libcaca' 'libcdio'
'libcdio-paranoia' 'libdrm' 'libdvdnav' 'libdvdread' 'libegl' 'libgl' 'libglvnd'
'libjpeg' 'libjpeg.so' 'libplacebo' 'libplacebo.so>=120-64' 'libpulse' 'libpulse.so'
'libva' 'libva.so' 'libva-drm.so' 'libva-wayland.so' 'libva-x11.so' 'libvdpau' 'libx11'
'libxext' 'libxinerama' 'libxkbcommon' 'libxkbcommon.so' 'libxrandr' 'libxss'
'libxv' 'luajit' 'mesa' 'mujs' 'pipewire' 'rubberband' 'librubberband.so' 'shaderc'
'libshaderc_shared.so' 'uchardet' 'vulkan-icd-loader' 'wayland' 'xdg-utils'
'zlib')
makedepends=('git' 'python-docutils' 'ladspa' 'wayland-protocols'
'ffnvcodec-headers' 'vulkan-headers' 'waf')
optdepends=('youtube-dl: for video-sharing websites playback')
provides=('libmpv.so' 'mpv')
conflicts=('mpv')
options=('!emptydirs')
validpgpkeys=('145077D82501AA20152CACCE8D769208D5E31419') # sfan5 <sfan5@live.de>
source=("git+https://github.com/mpv-player/mpv.git#tag=${_tag}?signed"
"Add-Pipewire-audio-backend.patch")
sha256sums=('SKIP'
'bf5d2a1642507198ade56244ba29fed121f10f2c60879f6b83148aabe74abb8c')
prepare() {
cd ${_pkgname}
git cherry-pick -n \
'79bfcc672343ddbc348e040ad899d61a0bafc050' \
'fc94c8c365ebeb038af6052bf4ea0506c1220559'
# patch the PipeWire audio backend (I had to remove the meson patch to make it build with the current release)
# https://github.com/mpv-player/mpv/pull/9587
patch -Np1 -i ../Add-Pipewire-audio-backend.patch
}
build() {
cd ${_pkgname}
waf configure --prefix=/usr \
--confdir=/etc/mpv \
--enable-cdda \
--enable-dvb \
--enable-dvdnav \
--enable-libarchive \
--enable-libmpv-shared \
--disable-build-date
waf build
}
package() {
cd ${_pkgname}
waf install --destdir="$pkgdir"
install -m0644 DOCS/{encoding.rst,tech-overview.txt} \
"$pkgdir"/usr/share/doc/mpv
install -m0644 TOOLS/lua/* \
-D -t "$pkgdir"/usr/share/mpv/scripts
}
|