blob: 530a772ae8439ddbffe317257a8f4f21782fdcc5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: cebtenzzre <cebtenzzre (AT) gmail (DOT) com>
# Contributor: Konstantin Shalygin <k0ste@k0ste.ru>
_pkgname=mstflint
pkgname=${_pkgname}425
_pkgver='4.25.0-1'
pkgver=${_pkgver//-/.}
pkgrel='1'
pkgdesc='Open-source version of MFT (Mellanox Firmware Tools) - old version for ConnectX-3 Pro'
arch=('x86_64' 'aarch64')
url="https://github.com/Mellanox/${_pkgname}"
license=('GPL-2.0-only OR Linux-OpenIB')
depends=('python' 'iniparser' 'openssl' 'libxml2' 'libidn2' 'libpsl'
'libunistring' 'zlib' 'xz' 'boost-libs' 'icu' 'keyutils' 'brotli'
'jsoncpp' 'curl' 'libnghttp2' 'sqlite')
makedepends=('rdma-core' 'boost')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
source=("${url}/archive/v${_pkgver}/${_pkgname}-${_pkgver}.tar.gz"
'0001-fix-missing-includes.patch')
sha256sums=('46f5fda9c8687bbcdae62145c17ad70f6b1725d738985eb3c8efd8c71604ddc3'
'28045b218edba0c38007d6812c38beb1afa05c707e59b49271ff0912e7b0ac74')
prepare() {
cd "${_pkgname}-${_pkgver}"
patch -Np1 -i ../0001-fix-missing-includes.patch
./autogen.sh
autoreconf -fvi
./configure \
--prefix="/usr" \
--sbindir="/usr/bin" \
--libexecdir="/usr/lib" \
--sysconfdir="/etc" \
--localstatedir="/var/${_pkgname}" \
--enable-fw-mgr \
--enable-xml2
}
build() {
cd "${_pkgname}-${_pkgver}"
make
}
package() {
cd "${_pkgname}-${_pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "README" "${pkgdir}/usr/share/doc/${pkgname}/README"
}
|