PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Isho Antar <0xisho@proton.me>

pkgname=mueller-dict
pkgver=3.1.1
pkgrel=1
pkgdesc="English -> Russian dictionary for dictd et al."
arch=('any')
url="http://mueller-dict.sourceforge.net"
license=('GPL2')
optdepends=('dictd: dict client and server')
# install="$pkgname.install"
source=(
    "http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
    "mueller-dict-"{install,remove}{,.hook}
)
sha1sums=(
    '6aebd3fdbe8f921e0011630d35137caf523fd40a'
    'e4464f3d3d39f50dda1320b61dabf3b175383dda' # install
    '11df4a93d604553edb1136317391af519ef8837c' # install hook
    '742adff8597df5372ca130ad6665841f94fb97a7' # remove
    '10a018ad44990a5ca7fd4fb56ec639866d248d23' # remove hook
)

prepare()
{
    cd "$pkgname-$pkgver"
    ./configure --prefix=/usr
}


build()
{
    make -C "$pkgname-$pkgver"
}


package()
{
    DESTDIR="$pkgdir" make -C "$pkgname-$pkgver" install
    mv "$pkgdir/usr/share/dict"{,d}

    install -m 0644 -Dt "$pkgdir/usr/share/doc/$pkgname/" \
        "$pkgname-$pkgver/"{AUTHORS,ChangeLog,INSTALL,NEWS,README,README.koi8r}

    install -m 0644 -Dt "$pkgdir/usr/share/libalpm/hooks" \
        "mueller-dict-"{install,remove}.hook
    install -m 0755 -Dt "$pkgdir/usr/share/libalpm/scripts" \
        "mueller-dict-"{install,remove}
}