blob: 942f7f039085211b1cf2f5549fcc15b7e6a426d6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: eolianoe <eolianoe At GoogleMAIL DoT CoM>
# Contributor: Michele Mocciola <mickele>
# Contributor: Guillaume Dollé <dolle dot guillaume at gmail dot com >
_pkgname=MUMPS
pkgname=${_pkgname,,}-seq
pkgver=5.7.2
pkgrel=1
pkgdesc="Sparse solver library using Gaussian elimination (sequential version)"
url="https://${_pkgname,,}-solver.org"
license=(CECILL-C)
depends=(gcc-libs lapack) # metis
makedepends=(gcc-fortran)
provides=(${_pkgname,,})
conflicts=(${_pkgname,,} ${_pkgname,,}-par ${_pkgname,,}-seq-shared)
arch=('i686' 'x86_64')
source=(${url}/${_pkgname}_${pkgver}.tar.gz
Makefile.inc
makefile_version.patch)
sha512sums=('90398b05ebf1573f06c8de2053d6384027b4a5a1dad2304bfd2b76cbd69eba2bbbcc374ce2226c36d6b331b5bdfcb9a3c99cad083ad711980524ac0da130182e'
'd7f076defe93704bf503612d0844f71698e2ca84b50ce551748c3b1bc972a2232c735a1ba02c038bf3468fe1eeac0411e66ed436339cb50978a3e2679c813364'
'bd9de5d4661ff4d6e30d20d62035c89b912a3e650aebf9ff5c57d424526180fac764e21f1da0aac5b619f067f007dc37afefaed1087716e8d61eeea1dfb2e8e7')
prepare() {
cd "${srcdir}"/${_pkgname}_${pkgver}
patch -p1 -i ../makefile_version.patch
cp "${srcdir}"/Makefile.inc .
}
build() {
cd "${srcdir}"/${_pkgname}_${pkgver}
make all
}
check() {
cd "${srcdir}"/${_pkgname}_${pkgver}/examples
make all
export LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${srcdir}/${_pkgname}_${pkgver}/lib"
./ssimpletest <input_simpletest_real
./dsimpletest <input_simpletest_real
./csimpletest <input_simpletest_cmplx
./zsimpletest <input_simpletest_cmplx
./c_example
./multiple_arithmetics_example
./ssimpletest_save_restore <input_simpletest_real
./dsimpletest_save_restore <input_simpletest_real
./csimpletest_save_restore <input_simpletest_cmplx
./zsimpletest_save_restore <input_simpletest_cmplx
./c_example_save_restore
}
package() {
# Install all headers
cd "${srcdir}/${_pkgname}_${pkgver}/include"
install -m 755 -d "${pkgdir}/usr/include"
install -D -m644 -- *.h "${pkgdir}/usr/include"
# Install all libraries
cd "${srcdir}/${_pkgname}_${pkgver}/lib"
install -m 755 -d "${pkgdir}/usr/lib"
install -D -m644 lib* ${pkgdir}/usr/lib
# Install mumps_seq headers
cd "${srcdir}/${_pkgname}_${pkgver}/libseq"
install -m 755 -d "${pkgdir}/usr/include/mumps_seq"
install -D -m644 -- *.h "${pkgdir}/usr/include/mumps_seq"
# Install mpiseq libraries
install -D -m644 lib* ${pkgdir}/usr/lib
# Install doc
install -m 755 -d "${pkgdir}/usr/share/doc/${pkgname}"
install -D -m644 "${srcdir}/${_pkgname}_${pkgver}/doc/userguide_${pkgver}.pdf" \
"${pkgdir}/usr/share/doc/${pkgname}/userguide_${pkgver}.pdf"
# Install examples
install -m 755 -d "${pkgdir}/usr/share/doc/${pkgname}/examples"
cd "${srcdir}/${_pkgname}_${pkgver}/examples"
install -m 644 * "${pkgdir}/usr/share/doc/${pkgname}/examples"
install -m 644 "${srcdir}"/${_pkgname}_${pkgver}/Makefile.inc "${pkgdir}/usr/share/doc/${pkgname}/examples"
sed -i 's_\(topdir =\).*_\1 /usr_g; s-.*\(Makefile.inc\)-include Makefile.inc-g' "${pkgdir}/usr/share/doc/${pkgname}/examples/Makefile"
rm -- "${pkgdir}/usr/share/doc/${pkgname}/examples/"*.o
# Install license
install -D -m644 "${srcdir}/${_pkgname}_${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|