PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=mupen64plus-highscore-git
pkgver=r25.b9b6bb3
pkgrel=1
pkgdesc="Highscore port of Mupen64Plus"
arch=('x86_64')
url="https://github.com/alice-mkh/mupen64plus-highscore"
license=('GPL-2.0-only')
depends=(
  'freetype2'
  'glu'
  'libgl'
  'libhighscore-git'
  'libpng'
  'sdl2'
  'zlib'
)
makedepends=(
  'git'
  'meson'
  'nasm'
  'yasm'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
options=('!lto')
source=('git+https://github.com/alice-mkh/mupen64plus-highscore.git'
        'git+https://github.com/mupen64plus/mupen64plus-core.git'
        'git+https://github.com/gonetz/GLideN64.git'
        'git+https://github.com/mupen64plus/mupen64plus-rsp-hle.git')
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

pkgver() {
  cd "${pkgname%-git}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${pkgname%-git}"
  git submodule init
  git config submodule.libs/mupen64plus-core.url "$srcdir/mupen64plus-core"
  git config submodule.libs/GLideN64.url "$srcdir/GLideN64"
  git config submodule.libs/mupen64plus-rsp-hle.url "$srcdir/mupen64plus-rsp-hle"
  git -c protocol.file.allow=always submodule update
}

build() {
#  CFLAGS+=" -ffat-lto-objects"
#  CXXFLAGS+=" -ffat-lto-objects"
  arch-meson "${pkgname%-git}" build
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir"
}