PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=mupen64plus-video-gliden64-highscore-git
pkgver=4.0.r701.g70b9b6c
pkgrel=1
pkgdesc="A new generation, open-source graphics plugin for Highscore port of Mupen64Plus"
arch=('x86_64')
url="https://github.com/gonetz/GLideN64"
license=('GPL-2.0-only')
depends=(
  'libglvnd'
  'mupen64plus-git'
)
makedepends=(
  'cmake'
  'git'
)
provides=('mupenplus-video-gliden64')
conflicts=('mupenplus-video-gliden64')
source=('git+https://github.com/gonetz/GLideN64.git'
        'gliden64-framebuffer-fix.patch')
sha256sums=('SKIP'
            'f1bae3a1b25106b004b75c70a3607fbe7bad94a92db2111c56f16ddc168f7178')

pkgver() {
  cd GLideN64
  git describe --long --tags --match "Public_Release*" --abbrev=7 | sed 's/^Public_Release_//;s/_/./;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd GLideN64

  # https://gitlab.gnome.org/World/highscore/-/raw/main/flatpak/cores/gliden64-framebuffer-fix.patch
  patch -Np1 -i ../gliden64-framebuffer-fix.patch
}

build() {
  cmake -B build -S GLideN64/src \
    -DCMAKE_BUILD_TYPE='RelWithDebInfo' \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DUSE_SYSTEM_LIBS='ON' \
    -DMUPENPLUSAPI='ON' \
    -DNO_OSD='ON' \
    -DNOHQ='ON' \
    -Wno-dev
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}