blob: a2ef26c51f26d3b5a73930492b39c0a56bf38f49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer : Kr1ss $(tr +- .@ <<<'<kr1ss+x-yandex+com>')
# Upstream author : Luke Smith <https://git{hub,lab}.com/lukesmithxyz/>
pkgname=mutt-wizard-git
_name="${pkgname%-git}"
pkgver() { git -C "$_name" describe --tags | sed 's/^v//;s/-/.r/;s/-/./g'; }
pkgver=3.2.1.r55.gc8bbef5
pkgrel=2
pkgdesc='Easily auto-configure neomutt and isync/mpop with safe passwords (IMAP/POP3/SMTP)'
arch=('any')
url="https://github.com/lukesmithxyz/$_name"
license=('GPL3')
provides=("$_name")
conflicts=("$_name")
makedepends=('git')
depends=('neomutt' 'isync' 'msmtp' 'notmuch-runtime' 'pass' 'curl' 'libnotify' 'perl')
optdepends=('imagemagick: view images inside of the neomutt TUI'
'w3m: view HTML email and images inside of the neomutt TUI'
'lynx: view HTML email inside of the neomutt TUI'
'links: view HTML email inside of the neomutt TUI'
'elinks: view HTML email inside of the neomutt TUI'
'urlview: list URLs found in mails to open them in a browser'
'abook: contact store and tab completion'
'protonmail-bridge: use neomutt with protonmail accounts'
'pam-gnupg: automatically unlock gpg keys at session login'
'cron: set up automatic mail syncing'
'mpop: if you want to use POP3 email access')
options=('zipman')
install="$_name.install"
source=("git+$url")
sha256sums=('SKIP')
package() {
cd "$_name"
make PREFIX=/usr DESTDIR="$pkgdir" -s install
install -Dm644 README.md -t"$pkgdir/usr/share/doc/$_name/"
}
# vim: ts=2 sw=2 et ft=PKGBUILD:
|