blob: cc58ba5c29b75ecf7c015eae9d5b06fbc6b2ad95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Joshua Haase <hahj87@gmail.com>
# Contributor: Matjaž Mozetič (https://github.com/sysadminmatmoz)
# Contributor: Vincent Demeester <vincent@sbr.pm>
# Contributor: Nicolas Pouillard (http://nicolaspouillard.fr)
# Contributor: Peter Simons <simons@cryp.to>
# Contributor: Andreas Hilboll <andreas@hilboll.de>
# Contributor: <kljohann@gmail.com>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>
pkgname=myrepos-git
pkgver=1.20180726.r101.ge58d3b8
pkgrel=2
pkgdesc='Multiple Repository management tool'
arch=(any)
url='https://myrepos.branchable.com/'
license=(GPL2)
depends=(perl)
makedepends=(git)
optdepends=('bzr: support for bzr repositories'
'cvs: support for cvs repositories'
'darcs: support for darcs repositories'
'git-annex: support for git-annex clones'
'git: support for git repositories'
'mercurial: support for mercurial repositories'
'perl-html-parser: support for webcheckout'
'perl-libwww: support for webcheckout'
'perl-uri: support for webcheckout heuristically guessing partial URLs'
'repo: support for repo repositories'
'svn: support for subversion repositories'
'unison: support for unison as a vcs'
'vcsh: support for vcsh')
provides=(mr "myrepos=$pkgver" webcheckout)
conflicts=(mr myrepos webcheckout)
source=("$pkgname::${url/#https/git}")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --long --abbrev=7 --tags --match='1.20*' |
sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$pkgname"
make
}
check() {
cd "$pkgname"
make test
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 -t "$pkgdir/usr/share/doc/${pkgname%-git}/" README
}
|