blob: 42f15258f4cb701997875573853e0793a6af692b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Sergio Correia <sergio@correia.cc>
# Contributor: Oleg Smirnov <oleg.smirnov@gmail.com>
# Contributor: Luke McCarthy <luke@iogopro.co.uk>
pkgname=nam
pkgver=1.15
pkgrel=6
pkgdesc="Tcl/TK based animation tool for viewing network simulation traces and real world packet traces"
url="http://www.isi.edu/nsnam/nam/"
license=('GPL')
arch=('i686' 'x86_64')
depends=('otcl')
makedepends=('tclcl')
source=(http://downloads.sourceforge.net/sourceforge/nsnam/nam-1/"${pkgver}"/nam-src-"${pkgver}".tar.gz
nam-1.15-tcl86.patch
nam-1.15-gcc61.patch)
sha256sums=('12ed547b3a5f8903890889d40cfea4d9bd66bb9ba6be99a0c753a9763cad8882'
'2766040c6c367a03efa43e81cbe178150fad6f4ee0b2b6d0b87292cb7c0bfe0b'
'b0ce4fb0b1fa6fe91ed26fd5daabede4521362f781364edcea4d7bff7d64472c')
prepare() {
cd "${srcdir}"/"${pkgname}"-"${pkgver}"
patch -uNp1 -i ../nam-1.15-tcl86.patch
patch -uNp1 -i ../nam-1.15-gcc61.patch
}
build() {
cd "${srcdir}"/"${pkgname}"-"${pkgver}"
./configure --prefix=/usr --with-tclcl=/usr/lib/tclcl
make
}
package() {
cd "${srcdir}"/"${pkgname}"-"${pkgver}"
install -d "${pkgdir}"/usr/bin
make DESTDIR="${pkgdir}" install
for dir in edu ex iecdemos bin; do
install -dm755 "${pkgdir}"/usr/share/nam/"${dir}"
install -m644 -t "${pkgdir}"/usr/share/nam/"${dir}" "${dir}"/*
done
}
# vim:set ts=2 sw=2 et:
|