blob: 5d3e23065282c97003bd06c7b89a7f8560960d94 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgname=nanoemoji
pkgver=0.15.1
pkgrel=2
pkgdesc='A wee tool to build color fonts'
arch=(any)
url="https://github.com/googlefonts/$_pkgname"
license=(Apache)
_py_deps=(cffsubr # optdepends of ufo2ft required for [cffsubr]
fonttools
fs # optdepends of fonttols required for [ufo]
lxml
pillow
regex
toml
ufo2ft
ufolib2)
depends=(absl-py
ninja
picosvg
python
"${_py_deps[@]/#/python-}")
makedepends=(python-{build,installer,wheel}
python-setuptools-scm)
optdepends=('resvg: Support CBDT and sbix color fonts')
checkdepends=(python-pytest
resvg)
_archive="$pkgname-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$_archive.tar.gz")
sha256sums=('12d4cf7947405e92dee9f17b2bedf681dfc0ab1f22d70099d175a782e63b9420')
prepare() {
cd "$_archive"
sed -i -e 's/^from ninja //' src/nanoemoji/ninja.py
}
build() {
cd "$_archive"
python -m build -wn
}
check() {
cd "$_archive"
# Skip tests that assume shell access to installed executable
PYTHONPATH=build/lib pytest \
--deselect tests/extract_svgs_test.py \
--deselect tests/maximum_color_test.py \
--deselect tests/nanoemoji_test.py
}
package() {
cd "$_archive"
python -m installer -d "$pkgdir" dist/*.whl
}
|