PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
pkgname=nbtutor
pkgdesc="Visualize Python code execution in Jupyter Notebook cells"
pkgver=2.0.3
pkgrel=4
arch=(any)
url="https://github.com/lgpage/${pkgname}"
license=('custom:BSD-3-clause')
depends=(jupyterlab)
makedepends=(python-build python-installer python-setuptools python-wheel jupyter_contrib_nbextensions)
checkdepends=(python-pytest)
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz)
sha512sums=('f55b69ce96c449ad7a1a623135ef94c6b54894680925cce14ea08ab5d1f409a17cd6c59876a8a2f6e8b63206b58c5afb2610c60c2fb2aebe0c0a8084599aebfd')

prepare() {
  sed -i 's/typeDict/sctypeDict/' ${pkgname}-${pkgver}/nbtutor/ipython/constants/types.py
}

build() {
  cd ${pkgname}-${pkgver}
  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd ${pkgname}-${pkgver}
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m pytest
}

package() {
  cd ${pkgname}-${pkgver}
  PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer --destdir="${pkgdir}" dist/*.whl
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  env PYTHONPATH="$pkgdir${site_packages}:PYTHONPATH" \
    JUPYTER_PATH="$pkgdir/usr/" \
    jupyter-nbextension install ${pkgname} --py --prefix="$pkgdir/usr/" --overwrite

  install -Dm 644 LICENCE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}