blob: 1ea7f4b8d2de9ff25897dec06c048eacbe1f6b4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Thomas Weißschuh <thomas t-8ch de>
pkgname=needrestart
url=https://github.com/liske/needrestart
pkgdesc='Restart daemons after library updates.'
pkgver=3.6
pkgrel=3
source=(
"needrestart-${pkgver}.tar.gz::https://github.com/liske/needrestart/archive/v${pkgver}.tar.gz"
'needrestart.hook'
)
arch=(any)
license=('GPL-2.0-or-later')
options=(!emptydirs)
depends=(perl-module-find
perl-term-readkey
perl-proc-processtable
perl-sort-naturally
perl-module-scandeps
perl-libintl-perl
)
optdepends=(
'iucode-tool: for outdated microcode detection'
)
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
make
}
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i -e 's|/usr/sbin|/usr/bin|' Makefile
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
make DESTDIR="${pkgdir}" install
install -Dm444 "${srcdir}/needrestart.hook" \
"${pkgdir}/usr/share/libalpm/hooks/needrestart.hook"
}
sha256sums=('3dced40d6116287b163da018d57014b0b7cee04794a95f8602126e2c296ed1a7'
'e5c6696a281f5445a3b7e2b7d1055f9189a2c39d4940721aa0c2718780f15f63')
|