PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>

pkgbase=neovim-zenbones
pkgname=('neovim-zenbones' 'vim-zenbones' 'neovim-zenbones-extras')
pkgver=4.11.0
pkgrel=1
_commit=22b7fb7
pkgdesc="Contrast-focused Neovim colorscheme"
arch=('any')
url="https://github.com/mcchrish/zenbones.nvim"
license=('MIT')
makedepends=('git')
source=("$pkgbase::git+$url#commit=$_commit?signed")
sha256sums=('b3a955730ff89c3fef6411cf34e6e7bb63c76a0de20a6d999f35db761c50d3fe')
validpgpkeys=('968479A1AFF927E37D1A566BB5690EEEBB952194')

package_neovim-zenbones() {
	groups=('neovim-plugins')
	depends=('neovim')
	optdepends=('neovim-lush: enhances included Lua-based colorschemes')
	provides=('neovim-lightline-zenbones' 'neovim-lualine-zenbones')
	conflicts=('neovim-lightline-zenbones' 'neovim-lualine-zenbones')
	install=zenbones.install

	cd "$pkgbase"
	find autoload doc colors lua \
		-type f -exec install -Dvm644 '{}' "$pkgdir/usr/share/nvim/site/pack/dist/start/$pkgname/{}" \;
	install -Dvm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
	install -Dvm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}

package_vim-zenbones() {
	pkgdesc="Contrast-focused Vim colorscheme"
	groups=('vim-plugins')
	depends=('vim')
	provides=('vim-lightline-zenbones')
	conflicts=('neovim-zenbones' 'vim-lightline-zenbones')

	cd "$pkgbase"
	find autoload doc colors \
		-type f -exec install -Dvm644 '{}' "$pkgdir/usr/share/vim/vimfiles/{}" \;
	install -Dvm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
	install -Dvm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}

package_neovim-zenbones-extras() {
	pkgdesc='Zenbones color templates for other programs'

	cd "$pkgbase"
	find extras -type f -exec install -Dvm644 '{}' "$pkgdir/usr/share/$pkgbase/{}" \;
	install -Dvm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}