PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Spike29 <leguen.yannick@gmail.com>
# Contributor: Lionel Hernou <lionel.hernou@gmail.com>

pkgname=netradiant-custom
pkgver=20241217
pkgrel=1
pkgdesc="The open-source, cross-platform level editor for id Tech based games (NetRadiant fork)"
arch=('x86_64')
url="https://garux.github.io/NRC/"
license=('Apache-2.0' 'BSD-3-Clause' 'GPL-2.0-or-later' 'LGPL-2.1-or-later' 'Zlib' 'LicenseRef-custom')
depends=('gcc-libs' 'glib2' 'glibc' 'libjpeg-turbo' 'libpng' 'libxml2' 'qt5-base' 'zlib')
makedepends=('git' 'unzip' 'wget')
optdepends=('xorg-xwayland: required to use the application on a Wayland session'
            'subversion: optional makedepend to fetch some gamepacks when using alternative DOWNLOAD_GAMEPACKS values')
provides=('h2data' 'mbspc' 'q2map' 'q3map2' 'qdata3')
source=("git+https://github.com/Garux/${pkgname}.git#tag=${pkgver}"
        "${pkgname}.desktop")
sha256sums=('08007e147a4a4f39629592f607822d0b38f38904ded37fab2ac565acd22e5865'
            'c9f21fbacdd2024e417234e986790fca67daeb391a91b590abb68b440e0df648')

build () {
	cd "${srcdir}/${pkgname}/"

	# Possible values for DOWNLOAD_GAMEPACKS are:
	# "yes" (free gamepacks only, downloaded from their respective sources)
	# "all" (free & proprietary gamepacks, downloaded from their respective sources)
	# "allinone" (free & proprietary gamepacks downloaded from a single archive, provided by the NRC maintainer)
	# "no"
 	# The "subversion" optdepend is needed when using the first 2 values
	make \
	 RADIANT_ABOUTMSG="NetRadiant-custom ${pkgver}" \
	 DOWNLOAD_GAMEPACKS=allinone
}

package () {
	mkdir -p "${pkgdir}/opt/${pkgname}"
	cp -r "${srcdir}/${pkgname}/install/"* "${pkgdir}/opt/${pkgname}/"

	# Add symlinks to /usr/bin and rename them so that this package can coexist with netradiant or gtkradiant
	mkdir -p "${pkgdir}/usr/bin"
	ln -s "/opt/${pkgname}/radiant" "${pkgdir}/usr/bin/${pkgname}"
	ln -s "/opt/${pkgname}/h2data" "${pkgdir}/usr/bin/h2data_nrc"
	ln -s "/opt/${pkgname}/mbspc" "${pkgdir}/usr/bin/mbspc_nrc"
	ln -s "/opt/${pkgname}/q2map" "${pkgdir}/usr/bin/q2map_nrc"
	ln -s "/opt/${pkgname}/q3map2" "${pkgdir}/usr/bin/q3map2_nrc"
	ln -s "/opt/${pkgname}/qdata3" "${pkgdir}/usr/bin/qdata3_nrc"

	# Install a desktop entry and the license file
	mkdir -p "${pkgdir}/usr/share/pixmaps"
	ln -s "/opt/${pkgname}/bitmaps/splash.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
	install -D -m644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
	install -D -m644 "${srcdir}/${pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}