blob: acf4be09f587f4e89d3f9ce72b8086836375b736 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Andreas Baumann <mail@andreasbaumann.cc>
pkgname=newsboat-og
pkgver=2.13.2
pkgrel=4
pkgdesc="An RSS/Atom feed reader for text terminals (old gen)"
arch=('x86_64' 'i486' 'i686' 'pentium4')
url="https://github.com/andreasbaumann/newsboat-og"
license=('MIT')
depends=('curl' 'hicolor-icon-theme' 'json-c' 'libxml2' 'sqlite' 'stfl')
makedepends=('asciidoc')
optdepends=('perl: for pinboard.pl'
'python: for exportOPMLWithTags.py'
'ruby: for feedgrabber.rb, heise.rb, and slashdot.rb')
replaces=('newsbeuter')
conflicts=('newsboat')
options=('!makeflags')
source=("$pkgname-$pkgver.tar.gz::https://github.com/andreasbaumann/$pkgname/archive/r$pkgver.tar.gz"
"$pkgname-curl-proxytype-cast.patch::https://github.com/andreasbaumann/$pkgname/commit/f2b404c3c4853d27f5def7d21e0040dcffc0fe61.patch"
"$pkgname-json-c-isystem.patch::https://github.com/andreasbaumann/$pkgname/commit/d11e3705b53cc219a47c7d6790faea841153d6c1.patch"
"$pkgname-image-count.patch::https://github.com/andreasbaumann/$pkgname/commit/ae260fcecc786ab07fd37df00105d410726883bc.patch"
"$pkgname-json-hpp-3.11.3.patch::https://github.com/andreasbaumann/$pkgname/commit/1ab71d889a38a4b3d8251da7c955d1ac1f362215.patch")
sha256sums=('b6646c92e87590b8780111a03ecda139faa846c1fb030bf02f0d89edbff9b8cc'
'83ae846553482e11d3ffae9c8190b167f2f83c3e08622e24df712a643d487907'
'48bdbf4fd88005d52a3c513d89dbfe5a2f9900419370259c9d7a3c7e4e1565b6'
'92213e3ed1b7f1eb1d8678a3f2c243c9592e7fab6e32af14df247ee1fbdfce91'
'93d152d5434a079a7bd2ca6b2a1e224bed002fb4e08058f62a42b60342fde533')
prepare() {
cd $pkgname-r$pkgver
patch -Np1 < ../newsboat-og-curl-proxytype-cast.patch
patch -Np1 < ../newsboat-og-json-c-isystem.patch
patch -Np1 < ../newsboat-og-image-count.patch
patch -Np1 < ../newsboat-og-json-hpp-3.11.3.patch
}
build() {
cd $pkgname-r$pkgver
make prefix=/usr
make doc
}
package() {
cd $pkgname-r$pkgver
make prefix=/usr DESTDIR="$pkgdir" install
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}
|