blob: 389e2805b392c50a4b453c32eabe1b57e358e108 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# $Id: PKGBUILD 103944 2014-01-13 20:31:53Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
pkgname=nextcloud-app-impersonate
_name=impersonate
pkgver=1.15.0
pkgrel=1
pkgdesc="Allow administrators to become a different user by adding an impersonate action to the user list"
arch=('any')
url="https://apps.nextcloud.com/apps/impersonate"
license=('GPL')
makedepends=('nextcloud' 'php' 'ripgrep' 'yq')
options=('!strip')
source=("$pkgname-$pkgver.tgz::https://github.com/nextcloud-releases/impersonate/releases/download/v$pkgver/impersonate-v$pkgver.tar.gz")
sha256sums=('7c9f7a3e6911be09a8218985eebff3390f3cfed8dbe9dd3eb10d586caabcb18f')
# BEGIN boilerplate nextcloud app version clamping, see also other packages in group
# 1. Call respective function helpers in check() and package() *after* cd'ing to the source directory
# 2. Add makedepends+=(nextcloud yq)
_phps=(php php-legacy)
_get_supported_ranges() {
_app_min_nextcloud="$(< appinfo/info.xml xq -r '.info.dependencies.nextcloud["@min-version"] | values')"
_app_max_nextcloud="$(< appinfo/info.xml xq -r '.info.dependencies.nextcloud["@max-version"] | values | tonumber | .+1')"
_app_min_php="$(< appinfo/info.xml xq -r '.info.dependencies.php["@min-version"] | values')"
_app_max_php="$(< appinfo/info.xml xq -r '.info.dependencies.php["@max-version"] | values | tonumber | .+0.1')"
}
_unsupported_range() {
printf "%s requires %s %s, but %s %s is provided.\n" "$pkgname" "$1" "$2" "$1" "$3"
exit 1
}
_nextcloud_app_check() {
_get_supported_ranges
for _php in "${_phps[@]}"; do command -v "$_php" > /dev/null && break; done
local _nextcloud_ver="$("$_php" <(cat /usr/share/webapps/nextcloud/version.php; echo 'print($OC_VersionString);'))"
local _php_ver="$("$_php" -r 'print(phpversion());')"
[[ "$(vercmp "${_app_min_nextcloud:-0}" "$_nextcloud_ver")" -le 0 ]] || \
_unsupported_range nextcloud "=> $_app_min_nextcloud" "$_nextcloud_ver"
[[ "$(vercmp "${_app_max_nextcloud:-999}" "$_nextcloud_ver")" -gt 0 ]] || \
_unsupported_range nextcloud "< $_app_max_nextcloud" "$_nextcloud_ver"
[[ "$(vercmp "${_app_min_php:-0}" "$_php_ver")" -le 0 ]] || \
_unsupported_range php ">= $_app_min_php" "$_php_ver"
[[ "$(vercmp "${_app_max_php:-999}" "$_php_ver")" -gt 0 ]] || \
_unsupported_range php "< $_app_max_php" "$_php_ver"
}
_nextcloud_app_package() {
_get_supported_ranges
depends+=("nextcloud>=${_app_min_nextcloud:-0}" "nextcloud<${_app_max_nextcloud:-999}")
depends+=("php-interpreter${_app_min_php:+>=$_app_min_php}" ${_app_max_php:+"php-interpreter<$_app_max_php"})
}
# END boilerplate nextcloud app version clamping
check() {
cd $_name
_nextcloud_app_check
}
package() {
install -d "${pkgdir}"/usr/share/webapps/nextcloud/apps
cp -a "${srcdir}"/impersonate "${pkgdir}"/usr/share/webapps/nextcloud/apps/impersonate
cd $_name
_nextcloud_app_package
}
|