PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92

# $Id: PKGBUILD 103944 2014-01-13 20:31:53Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>

pkgname=nextcloud-app-maps
_name=maps
pkgver=1.6.0
pkgrel=2
pkgdesc="OpenStreetMap layers including POIs"
arch=('any')
url="https://github.com/nextcloud/maps"
license=('GPL')
depends=('nextcloud')
makedepends=('ripgrep' 'yq' 'composer' 'npm')
options=('!strip')
#source=("https://github.com/nextcloud/maps/releases/download/v$pkgver/maps-$pkgver.tar.gz")
source=("$pkgname-$pkgver.tar.gz::https://github.com/nextcloud/maps/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('e5d39faa2bc9463546f361a2fd4ef23be90373553ee4ff1aabe39c97d0ecc8cc')

_get_nextcloud_versions() {
  _app_min_major_version="$(xq '.info.dependencies.nextcloud["@min-version"]' "${_name}-$pkgver/appinfo/info.xml"| sed 's/"//g')"
  _app_max_major_version="$(xq '.info.dependencies.nextcloud["@max-version"]' "${_name}-$pkgver/appinfo/info.xml"| sed 's/"//g')"
  _app_max_major_version=$(expr ${_app_max_major_version} + 1)
}

prepare() {
  cd "${srcdir}"/maps-$pkgver
  sed -i 's|composer bin all install --ansi|composer bin all install --ansi --ignore-platform-reqs -n|g' composer.json
}

build() {
  cd "${srcdir}"/maps-$pkgver

  composer install --ignore-platform-reqs -n
  npm ci
  npm run build

  rm -rf \
    .git \
    build \
    screenshots/addContacts.gif \
    screenshots/addFavorites.gif \
    screenshots/addPhotoFromFiles.gif \
    screenshots/addPhotosFromMap.gif \
    screenshots/addTracks.gif \
    screenshots/old-contacts.png \
    screenshots/old-start.png \
    screenshots/photoAlbumOnMap.gif \
    screenshots/shareMap.gif \
    tests \
    Makefile \
    *.log \
    phpunit*xml \
    composer.* \
    js/node_modules \
    node_modules \
    js/tests \
    js/test \
    js/*.log \
    js/package.json \
    js/bower.json \
    js/karma.* \
    js/protractor.* \
    babel.config.js \
    webpack.*.js \
    package.json \
    bower.json \
    karma.* \
    protractor\.* \
    translationfiles \
    .* \
    js/.*
}

check() {
  local _app_min_major_version
  local _app_max_major_version
  _get_nextcloud_versions

  local _nextcloud_major_version="$(rg "OC_Version = " /usr/share/webapps/nextcloud/version.php |cut -d'(' -f2| cut -d ',' -f1)"
  if [[ "$(vercmp "${_nextcloud_major_version}" "${_app_min_major_version}")" -lt 0 ]] || [[ "$(vercmp "${_nextcloud_major_version}" "${_app_max_major_version}")" -gt 0 ]] ; then
    printf "%s requires nextcloud >= %s/ nextcloud <= %s, but nextcloud %s is provided.\n" "$pkgname" "${_app_min_major_version}" "${_app_max_major_version}" "${_nextcloud_major_version}"
    exit 1
  fi
}

package() {
  _get_nextcloud_versions
  depends=("nextcloud>=${_app_min_major_version}" "nextcloud<${_app_max_major_version}")

  install -d "${pkgdir}"/usr/share/webapps/nextcloud/apps
  cp -r "${srcdir}"/maps-$pkgver "${pkgdir}"/usr/share/webapps/nextcloud/apps/maps
}