blob: 43e13279e450089b86ce3f37516dd5050a4284b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Carlos Galindo < arch -at_ cgj.es >
_appname=music
pkgname=nextcloud-app-music
pkgver=2.1.4
pkgrel=1
pkgdesc="Music app for Nextcloud and ownCloud"
arch=('any')
url="https://github.com/owncloud/music"
license=('AGPL-3.0-or-later')
makedepends=('npm' 'perl' 'perl-locale-po' 'unzip' 'zip' 'yq')
options=('!strip')
groups=('nextcloud-apps')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('1eeb5feb6415198af41eeb785475c94f233031e3240113e324bb9637a2a4470bb1653da60572c0bab3dcf96118f482419bd13333c51f3a5a8b13ffbd4728cfe5')
prepare() {
# Generate music.zip that is used when packaging
mv "$_appname-$pkgver" "$_appname"
zip -qr "$_appname.zip" "$_appname/"
# Remove creation of music.zip using git
cd "$_appname/build"
sed -i 's/^git/#git/' release.sh
}
build() {
cd "$_appname"
make -j1 -C build build
}
_get_nextcloud_versions() {
_app_min_major_version="$(xq '.info.dependencies.nextcloud["@min-version"]' "${_appname}/appinfo/info.xml"| sed 's/"//g')"
_app_max_major_version="$(xq '.info.dependencies.nextcloud["@max-version"]' "${_appname}/appinfo/info.xml"| sed 's/"//g')"
_app_max_major_version=$(expr ${_app_max_major_version} + 1)
}
package() {
local _app_min_major_version
local _app_max_major_version
_get_nextcloud_versions
depends=("nextcloud>=$_app_min_major_version" "nextcloud<$_app_max_major_version")
cd "$_appname"
_appsdir="$pkgdir/usr/share/webapps/nextcloud/apps"
_appdir="$_appsdir/$_appname"
mkdir -p "$_appsdir"
cp "../$_appname.zip" "$_appname.zip"
make -j1 -C build release
cd "$_appsdir"
unzip -q "$srcdir/music/music-nc.zip"
}
|