blob: 641748688c4a10394de9cfc3272d5229c805c765 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Contributor: Anty0 <anty150 at gmail dot com>
_name='ocdownloader'
pkgname=('nextcloud-app-ocdownloader')
pkgver=1.9.1
pkgrel=1
pkgdesc='Easy to use download manager using Curl/Aria2 and youtube-dl for Nextcloud'
arch=('any')
license=('AGPL3')
url="https://github.com/e-alfred/ocdownloader"
makedepends=('nextcloud' 'yq')
optdepends=(
'aria2: To use aria2 as download manager'
'curl: To download files using curl'
'youtube-dl: To download videos')
options=('!strip')
source=("${_name}-v${pkgver}.tar.gz::${url}/releases/download/${pkgver}/${_name}-${pkgver}.tar.gz")
sha512sums=('45f7ff16c39ab85f5134bc0a0b557302a93ed49c9897dbf5ae595f6938017531f96f6969f79852cb296f28768d418008b266492e36c6803a6a535206f703b1f9')
# BEGIN boilerplate nextcloud app version clamping, see also other packages in group
# 1. Call respective function helpers in check() and package() *after* cd'ing to the source directory
# 2. Add makedepends+=(nextcloud yq)
_phps=(php7 php php-legacy)
_get_supported_ranges() {
_app_min_nextcloud="$(< appinfo/info.xml xq -r '.info.dependencies.nextcloud["@min-version"] | values')"
_app_max_nextcloud="$(< appinfo/info.xml xq -r '.info.dependencies.nextcloud["@max-version"] | values | tonumber | .+1')"
_app_min_php="$(< appinfo/info.xml xq -r '.info.dependencies.php["@min-version"] | values')"
_app_max_php="$(< appinfo/info.xml xq -r '.info.dependencies.php["@max-version"] | values | tonumber | .+0.1')"
}
_unsupported_range() {
printf "%s requires %s %s, but %s %s is provided.\n" "$pkgname" "$1" "$2" "$1" "$3"
exit 1
}
_nextcloud_app_check() {
_get_supported_ranges
for _php in "${_phps[@]}"; do command -v "$_php" > /dev/null && break; done
local _nextcloud_ver="$("$_php" <(cat /usr/share/webapps/nextcloud/version.php; echo 'print($OC_VersionString);'))"
local _php_ver="$("$_php" -r 'print(phpversion());')"
[[ "$(vercmp "${_app_min_nextcloud:-0}" "$_nextcloud_ver")" -le 0 ]] || \
_unsupported_range nextcloud "=> $_app_min_nextcloud" "$_nextcloud_ver"
[[ "$(vercmp "${_app_max_nextcloud:-999}" "$_nextcloud_ver")" -gt 0 ]] || \
_unsupported_range nextcloud "< $_app_max_nextcloud" "$_nextcloud_ver"
[[ "$(vercmp "${_app_min_php:-0}" "$_php_ver")" -le 0 ]] || \
_unsupported_range php ">= $_app_min_php" "$_php_ver"
[[ "$(vercmp "${_app_max_php:-999}" "$_php_ver")" -gt 0 ]] || \
_unsupported_range php "< $_app_max_php" "$_php_ver"
}
_nextcloud_app_package() {
_get_supported_ranges
depends+=("nextcloud>=${_app_min_nextcloud:-0}" "nextcloud<${_app_max_nextcloud:-999}")
depends+=("php-interpreter${_app_min_php:+>=$_app_min_php}" ${_app_max_php:+"php-interpreter<$_app_max_php"})
}
# END boilerplate nextcloud app version clamping
check() {
cd $_name
_nextcloud_app_check
}
package() {
install -vdm 755 "$pkgdir/usr/share/webapps/nextcloud/apps/"
cp -av $_name "$pkgdir/usr/share/webapps/nextcloud/apps/"
cd $_name
_nextcloud_app_package
}
|