PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: Adrien Prost-Boucle <adrien.prost-boucle@laposte.net>
# Contributor: Peter Ivanov <ivanovp@gmail.com>
# Contributor: Aki-nyan <aur@catgirl.link>

_pkgname=nextpnr-himbaechel
pkgname=$_pkgname-git
pkgver=r4716.0d5d3295
pkgrel=1
pkgdesc="nextpnr portable FPGA place and route tool - Himbaechel backend for Xilinx"
arch=(x86_64)
url="https://github.com/YosysHQ/nextpnr"
license=("custom:ISC")

depends=("python" "boost-libs")
makedepends=("git" "gcc" "cmake" "pkgconf" "gawk" "eigen" "boost" "prjxray-db>=r258" "pypy3")
conflicts=("nextpnr")

source=(
	"$_pkgname::git+$url"
)
sha256sums=(
	'SKIP'
)

pkgver() {
	cd "$_pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "${srcdir}/$_pkgname"
	git submodule update himbaechel/uarch/xilinx/meta
}

build() {

	cmake -S "$_pkgname" -B build \
		-DARCH=himbaechel \
		-DHIMBAECHEL_XILINX_DEVICES="xc7z010;xc7z020" \
		-DHIMBAECHEL_PRJXRAY_DB="/usr/share/xray/database" \
		-DBUILD_PYTHON=OFF \
		-DBUILD_GUI=OFF \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DUSE_OPENMP=ON

	make -C build

}

package() {
	make -C build DESTDIR="${pkgdir}" install

	install -Dm644 "$_pkgname/COPYING" "${pkgdir}/usr/share/licenses/$pkgname/COPYING"

}