blob: b41fde1ebafb3cef25b29fe985380443342cc3a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
|
# Maintainer: KawaiDesu <mail@zeym.org>
# Contributor: @whoami
# Contributor: Roman Voropaev <voropaev.roma@gmail.com>
# Contributor: Julian Brost <julian@0x4a42.net>
# Contributor: Lorenzo Gabriele <lorenzolespaul@gmail.com>
# Contributor: Markus Hansmair <archlinux@zendro.de>
pkgbase='nginx-unit'
pkgname=('nginx-unitd'
'nginx-libunit'
'nginx-unit-python'
'nginx-unit-php-legacy'
'nginx-unit-php'
'nginx-unit-perl'
'nginx-unit-ruby'
'nginx-unit-nodejs'
'nginx-unit-go')
_shortname='unit'
pkgver=1.31.0
pkgrel=1
pkgdesc="Lightweight, dynamic, open-source server for diverse web applications."
arch=('i686' 'x86_64')
url="https://unit.nginx.org/"
license=('Apache')
source=("https://unit.nginx.org/download/unit-$pkgver.tar.gz"
'unit.service'
'configure.patch')
sha256sums=('268b1800bc4e030667e67967d052817437dff03f780ac0a985909aa225de61ed'
'8c9b2f732d6e50aa747aa7703303e5fff69f5abc6f5fc1741b774b422e029606'
'42ef974833acd61091b127a7b4b6cf5dc377948b78ef01eeb942d848e94c6b62')
makedepends=('php-embed' 'php-legacy-embed' 'python' 'go' 'ruby' 'perl' 'npm')
build() {
cd "${srcdir}/${_shortname}-${pkgver}"
# Fix linking wrong library (php instead of php-legacy)
patch --verbose -N auto/modules/php ../../configure.patch
./configure --prefix=/usr \
--sbindir=/usr/bin \
--modules="/usr/lib/$pkgbase" \
--state="/var/lib/$pkgbase" \
--pid="/run/$pkgbase.pid" \
--log="/var/log/$pkgbase.log" \
--control="/run/$pkgbase.control.sock" \
--tmp="/tmp" \
--openssl
./configure python --config=python3-config
./configure php --config=php-config-legacy --module=php-legacy --lib-name=php-legacy
./configure php
./configure perl
./configure ruby
./configure nodejs
./configure go --go-path=/usr/lib/go
make all
}
package_nginx-unitd() {
depends=('glibc' 'openssl')
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="${pkgdir}" unitd-install
install -m 644 -D "${srcdir}/unit.service" "${pkgdir}/usr/lib/systemd/system/unit.service"
}
package_nginx-libunit() {
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="${pkgdir}" libunit-install
}
package_nginx-unit-python() {
depends=('nginx-unitd' 'python')
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="${pkgdir}" python3-install
}
package_nginx-unit-php-legacy() {
depends=('nginx-unitd' 'php-legacy-embed')
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="${pkgdir}" php-legacy-install
}
package_nginx-unit-php() {
depends=('nginx-unitd' 'php-embed')
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="${pkgdir}" php-install
}
package_nginx-unit-go() {
arch=('any')
depends=('nginx-unitd' 'go')
cd "${srcdir}/${_shortname}-${pkgver}"
export CGO_CFLAGS_ALLOW='-Wp,-D_FORTIFY_SOURCE=2,-D_GLIBCXX_ASSERTIONS|-fcf-protection'
make DESTDIR="${pkgdir}" go-install
}
package_nginx-unit-perl() {
arch=('any')
depends=('nginx-unitd' 'perl')
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="${pkgdir}" perl-install
}
package_nginx-unit-ruby() {
arch=('any')
depends=('nginx-unitd' 'ruby')
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="$pkgdir" ruby-install
}
package_nginx-unit-nodejs() {
arch=('any')
depends=('nginx-unitd' 'nodejs')
cd "${srcdir}/${_shortname}-${pkgver}"
make DESTDIR="${pkgdir}/usr/lib/" node-local-install
}
|