blob: e23010b4fc20b2d974b18db4085190bb0891cd23 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Piyush Pangtey <pangteypiyush @ gmail.com>
pkgname=nodejs-lts-carbon
pkgver=8.9.1
pkgrel=1
pkgdesc='Evented I/O for V8 javascript'
arch=('i686' 'x86_64')
url='http://nodejs.org/'
license=('MIT')
depends=('openssl-1.0' 'zlib' 'icu' 'libuv' 'http-parser' 'c-ares') # 'v8')
makedepends=('python2' 'procps-ng')
optdepends=('npm: nodejs package manager')
conflicts=('nodejs')
provides=('nodejs')
source=("nodejs-$pkgver.tar.gz::https://github.com/nodejs/node/archive/v$pkgver.tar.gz")
sha512sums=("01d8b235943568ae37f440d45ae19697fb67505d408b1220c5ed5238a8d5a3ed5646b922800303fd0e1d936e7f83122b97faeb81b11bb8618c550f5be20b4273")
prepare() {
cd node-$pkgver
msg 'Fixing for python2 name'
find -type f -exec sed \
-e 's_^#!/usr/bin/env python$_&2_' \
-e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
-e 's_^#!/usr/bin/python$_&2_' \
-e 's_^\( *exec \+\)python\( \+.*\)$_\1python2\2_'\
-e 's_^\(.*\)python\( \+-c \+.*\)$_\1python2\2_'\
-e "s_'python'_'python2'_" -i {} \;
find test/ -type f -exec sed 's_python _python2 _' -i {} \;
}
build() {
cd node-$pkgver
export PKG_CONFIG_PATH=/usr/lib/openssl-1.0/pkgconfig
export PYTHON=python2
./configure \
--prefix=/usr \
--with-intl=system-icu \
--without-npm \
--shared-openssl \
--shared-zlib \
--shared-libuv \
--shared-http-parser \
--shared-cares
# --shared-v8
make
}
check() {
cd node-$pkgver
# Expected failure: https://github.com/nodejs/node/issues/11627
make test || warning "Tests failed"
}
package() {
cd node-$pkgver
make DESTDIR="$pkgdir" install
install -D -m644 LICENSE \
"$pkgdir"/usr/share/licenses/nodejs/LICENSE
}
|