blob: a431f695a14c834bad21c72f32a0c01258f4797e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
_npmname=mapscii
_npmver=0.3.1
pkgname=nodejs-mapscii
pkgver=$_npmver
pkgrel=4
pkgdesc="Map+Ascii -> MapSCII! Console Map Viewer."
arch=(any)
url="https://github.com/rastapasta/mapscii#readme"
license=('MIT')
depends=('nodejs')
makedepends=('npm' 'jq')
source=(https://registry.npmjs.org/$_npmname/-/$_npmname-$_npmver.tgz)
noextract=($_npmname-$_npmver.tgz)
sha1sums=(fecb9e96de9408effa8819cf83e5a5d379324198)
package() {
npm install -g --prefix "$pkgdir/usr" "$srcdir/$_npmname-$pkgver.tgz"
# Non-deterministic race in npm gives 777 permissions to random directories.
# See https://github.com/npm/cli/issues/1103 for details.
find "${pkgdir}/usr" -type d -exec chmod 755 {} +
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "${pkgdir}"
# Remove references to pkgdir
find "$pkgdir" -name package.json -print0 | xargs -r -0 sed -i '/_where/d'
# Remove references to srcdir
local tmppackage="$(mktemp)"
local pkgjson="$pkgdir/usr/lib/node_modules/$_npmname/package.json"
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
mv "$tmppackage" "$pkgjson"
chmod 644 "$pkgjson"
}
# vim:set ts=2 sw=2 et:
|