blob: e41bd56f176b92714f2692938c6ee068336a5c42 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Nick Black <dankamongmen@gmail.com>
pkgname=notcurses
pkgver=2.4.9
pkgrel=1
pkgdesc="Blingful TUI/character graphics library"
url="https://nick-black.com/dankwiki/index.php/Notcurses"
license=('Apache')
arch=('x86_64' 'aarch64')
# qrcodegen is currently shipped as a static archive on Arch, rather than a
# dynamic library. Should the .so be shipped in the future, promote qrcodegen
# from a makedepends to a true depends, and use that dynamic library.
depends=('ncurses' 'ffmpeg' 'libunistring')
makedepends=('cmake' 'pandoc' 'python-pip' 'python-pypandoc' 'python-cffi' 'python-setuptools' 'doctest' 'qrcodegen' 'ninja' 'zlib' 'gpm')
source=("https://github.com/dankamongmen/notcurses/archive/v${pkgver}.tar.gz")
prepare() {
mkdir -p "${pkgname}-${pkgver}/build"
cd "${pkgname}-${pkgver}/build"
cmake .. -GNinja -DCMAKE_INSTALL_PREFIX="/usr" -DCMAKE_BUILD_TYPE=RelWithDebInfo -DUSE_QRCODEGEN=on -DUSE_GPM=on
}
build() {
cd "${pkgname}-${pkgver}/build"
ninja
}
check() {
cd "${pkgname}-${pkgver}/build"
ninja test
}
package() {
cd "${pkgname}-${pkgver}/build"
DESTDIR="$pkgdir" ninja install
cd ../cffi
env CFLAGS="-I$pkgdir/usr/include -L../build" python setup.py install --root="$pkgdir" --optimize=1
}
sha256sums=('a2771ad1633e0158f8273fa8b30b5bce0f12e1205e863045f4ae186b6b52f537')
|