PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Jesse Bryan <jesse@winneon.moe>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=nototools-git
pkgver=0.2.13.r26.g1b452b0
pkgrel=1
epoch=1
pkgdesc='Noto fonts support tools and scripts plus web site generation'
url="https://github.com/googlefonts/${pkgname%-git}"
arch=(any)
license=(Apache)
_pydeps=(appdirs
         attrs
         black
         booleanoperations
         brotli
         click
         defcon
         defcon
         fontmath
         fontparts
         fontpens
         fonttools
         fs
         lxml
         mutatormath
         pathspec
         pillow
         pillow
         pyclipper
         pyclipper
         pytz
         regex
         six
         toml
         typed-ast
         ufolib2
         ufonormalizer
         ufoprocessor
         unicodedata2
         zopfli)
depends=(afdko
         cairo
         harfbuzz
         imagemagick
         pango
         psautohint
         python
         "${_pydeps[@]/#/python-}"
         scour)
makedepends=(git python-setuptools-scm)
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')

pkgver() {
	cd "$pkgname"
	git describe --long --tags --abbrev=7 --match="v*" HEAD |
		sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "$pkgname"
	python setup.py build
}

package() {
	cd "$pkgname"
	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}