PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

# Maintainer: D-Jy <duan@d-jy.net>

pkgbase='nps'
pkgname=('nps' 'npc')
pkgver=0.29.30
pkgrel=1
pkgdesc="A lightweight, high-performance intranet penetration proxy with web UI"
arch=('x86_64' 'i686' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/djylb/nps"
license=('GPL3')
depends=('glibc')
makedepends=('go')
install='.INSTALL'
source=(
  "${pkgbase}-${pkgver}.tar.gz::https://github.com/djylb/nps/archive/refs/tags/v${pkgver}.tar.gz"
  "npc.service"
  "nps.service"
)
sha256sums=('9874c7e4f5352a6e89f9833aa47b1a7b0e8391c14ee05ed13ac35a64a28b1a50'
            'c668c61dc1d61f87c75430277c4962e71860ab066d3acaaab578b811b781b33e'
            'da9a34b86e9d9f42c0fb57f23b887de89d9de0d7c6a0f6fb34d6741755d35237')

prepare() {
  cd ${srcdir}/${pkgbase}-${pkgver}
  mkdir -p build
}

build() {
  cd ${srcdir}/${pkgbase}-${pkgver}
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"

  go build -o build/npc ./cmd/npc/npc.go
  go build -o build/nps ./cmd/nps/nps.go
}

packaging() {
  install -Dm 755 build/${1} ${pkgdir}/usr/bin/${1}
  install -Dm 644 ${srcdir}/${1}.service ${pkgdir}/usr/lib/systemd/system/${1}.service

  for conf in $2
  do
    install -Dm644 conf/$(basename "$conf") -t ${pkgdir}/etc/${pkgbase}/conf/
  done
}

package_npc() {
  cd ${srcdir}/${pkgbase}-${pkgver}

  _name=`echo ${FUNCNAME} | cut -d _ -f 2`

  backup=(
    "etc/${pkgbase}/conf/npc.conf"
    "etc/${pkgbase}/conf/multi_account.conf"
  )

  packaging "${_name}" "${backup[*]}"
}

package_nps() {
  cd ${srcdir}/${pkgbase}-${pkgver}

  _name=`echo ${FUNCNAME} | cut -d _ -f 2`

  backup=(
    "etc/${pkgbase}/conf/nps.conf"
  )

  packaging "$_name" "${backup[*]}"

  install -d "${pkgdir}/etc/${pkgbase}/web/views" "${pkgdir}/etc/${pkgbase}/web/static"
  find web/views  -type f -exec install -Dm644 {} "${pkgdir}/etc/${pkgbase}/{}" \;
  find web/static -type f -exec install -Dm644 {} "${pkgdir}/etc/${pkgbase}/{}" \;
}