blob: 8783db77f30195437c0b2cafab2d9dc68a6de085 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Panagiotis Mavrogiorgos <pmav99@gmail.com>
pkgname=nuitka
pkgver=2.1.5
pkgrel=1
pkgdesc='Python compiler with full language support and CPython compatibility'
arch=(any)
url='https://nuitka.net'
license=(Apache-2.0)
depends=(libxml2 patchelf python-appdirs python-setuptools python-wheel scons)
makedepends=(gdb python-build python-installer git)
checkdepends=(ccache fuse2 python-boto3 python-brotli strace)
optdepends=('ccache: for caching builds')
source=("$url/releases/${pkgname^}-$pkgver.tar.bz2")
b2sums=('7ca8b31a02853912ec7b6e8e0912d8dd8249888ce3cb1a1abe979dbe926f9763968ec2ffaea8b9d75bc9efa2df0b7739b861401291f3aad33b19f634fd6c5fce')
build() {
cd ${pkgname^}-$pkgver
python -m build --wheel --no-isolation
}
check() {
cd ${pkgname^}-$pkgver
# Check that compilation works
echo 'print("[x] Can compile main.py to an executable.\n[x] Can run the resulting executable.")' > main.py
bin/nuitka --output-filename=main --lto=yes --show-scons main.py
./main
# Tests are disabled for now. See:
# https://github.com/Nuitka/Nuitka/issues/2595
# https://github.com/Nuitka/Nuitka/issues/2609
#cd tests
#./run-tests
}
package() {
cd ${pkgname^}-$pkgver
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm 644 {Changelog,Developer_Manual,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
}
|