blob: d8cfd310e094315fd4cd99127520b7dc0e735a1a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Mahdi Sarikhani <mahdisarikhani@outlook.com>
pkgname=oblivion-desktop
pkgver=2.45.0
pkgrel=1
pkgdesc="Unofficial Warp Client"
arch=('x86_64')
url="https://github.com/bepass-org/oblivion-desktop"
license=('LicenseRef-oblivion-desktop')
_electron=electron33
depends=('bash' "${_electron}")
makedepends=('gendesk' 'npm')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
"${pkgname}.sh")
sha256sums=('319f29a8d486bdeab99aefb25a22e49eff3b1f056322a2ea27d9502d36425dfe'
'31676f8268a42b7cc292e7e8d71e8dab3f41f9b4a5332471134428d821b4338f')
prepare() {
cd "${pkgname}-${pkgver}"
sed "s/process.resourcesPath/path.dirname(app.getAppPath())/" -i src/main/main.ts
sed "s/@ELECTRON@/${_electron}/" -i "${srcdir}/${pkgname}.sh"
gendesk -f -n \
--pkgname "${pkgname}" \
--pkgdesc "${pkgdesc}" \
--name 'Oblivion Desktop' \
--categories 'Utility' \
--custom StartupWMClass='Oblivion Desktop'
npm install
}
build() {
cd "${pkgname}-${pkgver}"
npm run build
npx electron-builder --linux --dir \
-c.electronDist="/usr/lib/${_electron}" \
-c.electronVersion="$(cat /usr/lib/${_electron}/version)"
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm644 release/build/linux-unpacked/resources/app.asar -t "${pkgdir}/usr/lib/${pkgname}"
cp -r release/build/linux-unpacked/resources/assets "${pkgdir}/usr/lib/${pkgname}"
install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
install -Dm644 assets/icon.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -Dm644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|