PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Giovanni Santini <itachi.sama.amaterasu@gmail.com>
# Contributor: Dustin Falgout <dustin@antergos.com>

pkgname=obs-service-tar_scm-git
pkgver=0.10.48.r835
pkgrel=1
pkgdesc="Source Service for the OpenSUSE Build Service (OBS)"
arch=('any')
url="https://github.com/openSUSE/obs-service-tar_scm"
license=('GPL3')
source=("${pkgname}::git+${url}.git")
groups=('obs')
depends=('python'
         'obs-build'
         'git'
         'python-yaml'
         'python-dateutil')
checkdepends=('flake8'
              'python-mock'
              'python-pylint'
              'bzr'
              'cpio'
              'mercurial'
              'subversion')
optdepends=('cpio: needed for running properly the obs_scm source service'
            'subversion: svn repo support.'
            'mercurial: hg repo support.'
            'bzr: bzr repo support.')
backup=("etc/obs/services/tar_scm")
sha256sums=('SKIP')
# Comment this line to run tests
BUILDENV+=('!check')

pkgver() {
    cd "${srcdir}/${pkgname}"
    printf "%s.r%s" "$(git describe --tags --abbrev=0)" "$(git rev-list --count HEAD)"
}

check() {
    cd "${srcdir}/${pkgname}"
    make check
}

package() {
    cd "${srcdir}/${pkgname}"
    make DESTDIR="${pkgdir}" PREFIX=/usr install
}