blob: 84a934ddafe6e7634811e42dbc7efbe40defefa6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Mort Yao <soi@mort.ninja>
# Co-Maintainer: Felix Golatofski <contact@xdfr.de>
# Co-Maintainer: Xunarui Qi <me@xuanruiqi.com>
# Contributor: Serge Zirukin <ftrvxmtrx@gmail.com>
# Contributor: Sergei Lebedev <superbobry@gmail.com>
# Contributor: Guillem Rieu <guillemr@gmx.net>
# Contributor: Sergey Plaksin <serp256@gmail.com>
# Contributor: Nicolas Pouillard <nicolas.pouillard@gmail.com>
pkgname=ocaml-menhir
pkgver=20231231
pkgrel=1
pkgdesc="Menhir is a LR(1) parser generator for the OCaml."
arch=("x86_64")
url="http://cristal.inria.fr/~fpottier/menhir/"
license=('GPL' 'QPL')
depends=('ocaml>=4.03.0')
makedepends=('dune>=2.8.0' 'ocaml-findlib')
options=(!strip !makeflags)
source=("https://gitlab.inria.fr/fpottier/menhir/-/archive/${pkgver}/menhir-${pkgver}.tar.gz")
sha256sums=('783e95e1ce7f1082c5c693810732344ac3e443a255b822acfca46dd985cfedae')
build() {
cd "$srcdir/${pkgname/ocaml-/}-$pkgver"
dune build
}
package() {
cd "$srcdir/${pkgname/ocaml-/}-$pkgver"
dune install --destdir="${pkgdir}" --prefix="/usr" \
--libdir="$(ocamlfind printconf destdir)"
install -dm755 "${pkgdir}/usr/share/"
mv "${pkgdir}/usr/doc" "${pkgdir}/usr/share/"
}
|